Question

我有一个需要转换的场景：

<Hand id="left">
    <FingerOne>Thumb</FingerOne>
    <FingerTwo>Pointer</FingerTwo>
    <FingerThree>Middle</FingerThree>
</Hand>

要：

<Hand id="left" F1="Thumb" F2="Pointer" F3="Middle" />

我一直在使用这段XSLT将嵌套的实体标签转换为属性，这很有用。我不确定如何将名称“FingerOne”更改为1，将“FingerTwo”更改为2，等等，同时将元素移动到属性中。

<xsl:for-each select="*">
    <xsl:attribute name="{name()}">
        <xsl:value-of select="text()"/>
    </xsl:attribute>
</xsl:for-each>

我找到了这个答案https://stackoverflow.com/a/8274527/857994，它显示了如何使用基本上是地图来进行转换。我似乎无法在我的文档中使它工作。

注意，我正在尝试使用JAXP在Java的XSLT功能构建中完成这项工作。它似乎不支持许多XSLT2.0功能，所以如果你能坚持使用XSLT1.0，我将非常感激。

Answer 1

这是一个自包含的选项，不需要任何外部XML文件。

当这个XSLT：

<?xml version="1.0"?>
<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:my="my"
  exclude-result-prefixes="my"
  version="1.0">
  <xsl:output omit-xml-declaration="yes" indent="yes"/>
  <xsl:strip-space elements="*"/>

  <my:attributeNames>
    <name original="FingerOne" new="F1"/>
    <name original="FingerTwo" new="F2"/>
    <name original="FingerThree" new="F3"/>
  </my:attributeNames>

  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="Hand/*">
    <xsl:attribute
      name="{document('')/*/my:attributeNames/*
                            [@original = name(current())]/@new}">
      <xsl:value-of select="."/>
    </xsl:attribute>
  </xsl:template>
</xsl:stylesheet>

...适用于提供的XML：

<Hand id="left">
  <FingerOne>Thumb</FingerOne>
  <FingerTwo>Pointer</FingerTwo>
  <FingerThree>Middle</FingerThree>
</Hand>

...生成了想要的结果：

<Hand id="left" F1="Thumb" F2="Pointer" F3="Middle" />

<强>解释

注意元素的<my:attributeNames>“数组”;此外，请注意“旧”和“新”值如何作为属性包含在这些元素中。
通过使用document('')指令访问这些值，该指令指示解析器从当前文档中收集元素。

或者，这是一个不同的XSLT 1.0解决方案。如果出现以下情况可能会更有用：

document('')由于某种原因，在您的环境中无法使用。

OR

在XSLT中使用伪字典似乎有点笨拙（而且你愿意做一个小假设）。

当这个XSLT：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:output omit-xml-declaration="yes" indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:variable name="vStartingChar" select="'F'" />

  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="Hand/*">
    <xsl:attribute
      name="{concat($vStartingChar, count(preceding-sibling::*) + 1)}">
      <xsl:value-of select="."/>
    </xsl:attribute>
  </xsl:template>
</xsl:stylesheet>

...对同一输入XML应用，再次生成所需结果：

<Hand id="left" F1="Thumb" F2="Pointer" F3="Middle" />

<强>解释

注意在XSLT顶部定义的变量：

<xsl:variable name="vStartingChar" select="'F'" />

这提供了一种方便的机制来更改新属性的起始字符。如前所述，如果相同的模式继续（即，其他属性将遵循相同的方案 - F4，F5等），此解决方案更好，因为它不需要你更新元素的“数组”。

Answer 2

如果您想使用字典方法，首先应在名为dict.xml的文件中创建字典：

<dict>
    <entry name="FingerOne">F1</entry>
    <entry name="FingerTwo">F2</entry>
    <entry name="FingerThree">F3</entry>
</dict>

然后你可以写下这样的转换：

<xsl:variable name="dict" select="document('dict.xml')/dict"/>

<xsl:template match="Hand">
    <xsl:copy>
        <xsl:copy-of select="@*"/>
        <xsl:apply-templates select="*" mode="map-to-attr"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="*" mode="map-to-attr">
    <xsl:attribute name="{$dict/entry[@name=name(current())]}">
        <xsl:value-of select="."/>
    </xsl:attribute>
</xsl:template>

使用XSLT将元素更改为属性并缩短名称

2 个答案: