Question

在我的代码中，我将first，middle和lastname绑定到一个名称，然后使用名称对其进行排序。

我想以升序对绑定名称进行排序，并且在排序列表的末尾应显示没有名字的名称。

请分享您的想法以解决此问题。

我的代码：

bind ( COALESCE(?firstName, "") As ?firstName1).

bind ( COALESCE(?middleName, "") As ?middleName1).

bind ( COALESCE(?lastName, "") As ?lastName1).

bind (concat(str(?firstName1),str(?middleName1),str(?lastName1)) as ?name).

}

order by (regex(" " ,?firstName1) && bound (?name))

在输出中虽然名称为空的名称最后出现，但其余名称未按asc顺序排序。

Answer 1

根据我的理解，您希望按字典顺序排序名称（按名字排序，然后按中间名排序，然后按姓氏排序），但有一个例外：而不是使用 no 输入条目在开头的名字，你想把它们放在最后。如果这是正确的，您需要一个订购条件，如：

ORDER BY DESC( bound( ?firstName )) ?firstName ?middleName ?lastName

这是一些可以使用的RDF，其中:fn，:mn和:ln分别代表名字，中间名和姓氏：

@prefix : <http://www.example.org/>.

:aaa :fn "A"; :mn "A"; :ln "A".
:aab :fn "A"; :mn "A"; :ln "B".
:aba :fn "A"; :mn "B"; :ln "A".

:_aa          :mn "A"; :ln "A".
:_ab          :mn "A"; :ln "B".
:_ba          :mn "B"; :ln "A".

此SPARQL可选择绑定?firstName的数据，并按上述顺序排序：

PREFIX : <http://www.example.org/>

SELECT ?firstName ?middleName ?lastName
WHERE {
             ?x :mn ?middleName .
             ?x :ln ?lastName .
  OPTIONAL { ?x :fn ?firstName . }
}
ORDER BY DESC( bound( ?firstName )) ?firstName ?middleName ?lastName

调用数据names.n3和查询names.sparql，以下是我使用Jena的ARQ对数据运行查询时得到的结果：

$ /usr/local/lib/apache-jena-2.10.0/bin/arq --data names.n3 --query names.sparql
-------------------------------------
| firstName | middleName | lastName |
=====================================
| "A"       | "A"        | "A"      |
| "A"       | "A"        | "B"      |
| "A"       | "B"        | "A"      |
|           | "A"        | "A"      |
|           | "A"        | "B"      |
|           | "B"        | "A"      |
-------------------------------------

即使您预测?name而不是?firstName，?middleName或?lastName，您仍然可以按此方式进行排序。例如，查询

PREFIX : <http://www.example.org/>

SELECT ?name
WHERE {
             ?x :mn ?middleName .
             ?x :ln ?lastName .
  OPTIONAL { ?x :fn ?firstName . }

  bind ( concat( str(coalesce(?firstName, "_")), str(?middleName), str(?lastName) ) as ?name).
}
ORDER BY DESC( bound( ?firstName )) ?firstName ?middleName ?lastName

生成

---------
| name  |
=========
| "AAA" |
| "AAB" |
| "ABA" |
| "_AA" |
| "_AB" |
| "_BA" |
---------

Sparql：如果名字为空，则在最后一个排序列表中显示名称

1 个答案: