Question

如何编写通过HTTP帖子接收文件的Perl CGI脚本并将其保存到文件系统？

Answer 1

my $fh = $query->upload('upload_field');
while(<$fh>) {
  print SAVE_FILE $_;
}

Answer 2

请注意：不过，您会写下来，不要将其保存在可从您的网络服务器访问的地方。

现在到了这一点：下面是我用了一段时间进行照片上传的脚本。它可能需要一些调整，但应该告诉你的方式。

由于图像没有上传到网页可访问的目录，我们会对其进行单独的过程检查，调整大小，设置水印并将其放置在可以访问的位置。

 #!/usr/bin/perl -wT

use strict;
use CGI;
use CGI::Carp qw ( fatalsToBrowser );
use File::Basename;

$CGI::POST_MAX = 1024 * 5000;
my $safe_filename_characters = "a-zA-Z0-9_.-";
my $upload_dir = "/home/www/upload";

my $query = new CGI;
my $filename = $query->param("photo");
my $email_address = $query->param("email_address");

if ( !$filename )
{
 print $query->header ( );
 print "There was a problem uploading your photo (try a smaller file).";
 exit;
}

my ( $name, $path, $extension ) = fileparse ( $filename, '\..*' );
$filename = $name . $extension;
$filename =~ tr/ /_/;
$filename =~ s/[^$safe_filename_characters]//g;

if ( $filename =~ /^([$safe_filename_characters]+)$/ )
{
 $filename = $1;
}
else
{
 die "Filename contains invalid characters";
}

my $upload_filehandle = $query->upload("photo");

open ( UPLOADFILE, ">$upload_dir/$filename" ) or die "$!";
binmode UPLOADFILE;

while ( <$upload_filehandle> )
{
 print UPLOADFILE;
}

close UPLOADFILE;

print $query->header ( );
print <<END_HTML;
<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "DTD/xhtml1-strict.dtd">
<html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
 <head>
   <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
   <title>Thanks!</title>
 </head>
 <body>
   <p>Thanks for uploading your photo!</p>
 </body>
</html>
END_HTML

Answer 3

请参阅the CGI.pm documentation for file uploads。

Answer 4

我首先使用CGI并阅读CREATING A FILE UPLOAD FIELD，然后使用open创建文件，并使用print写入文件。（然后close关闭它。）

如何处理HTTP文件上传？

4 个答案: