Question

我构建了一个函数来搜索和替换整个Excel文档中的特定文本。我可以使用

完成整个文档及其所有单元格

For Each WS In Worksheets
    For Each ActiveCell In WS.UsedRange
        If ActiveCell <> "" Then
            ActiveCell.Value = ReplaceWord(ActiveCell.Value, Search, Replacement)
        End If
     next
next

这很有效，但很多文档都有文本框和其他地方标题的图表，我不知道如何在不知道其确切名称等的情况下访问这些标题。基本上我想搜索excel文档中的每个字符串，并使用我的ReplaceWord函数来替换单词。但我迷失在如何：）

非常感谢任何帮助。谢谢！

Answer 1

您似乎必须遍历图表的属性。您可以使用VBE中的locals窗口查看cht变量设置后的其他属性。这不是一个详尽的选项列表，但它应该足以让你开始！

Sub ReplaceTextInChart()

Dim cObj As ChartObject
Dim cht As Chart
Dim ax As Axis
Dim legEnt As LegendEntry
Dim srs As Series

Dim str As String 'this variable will use to hold the various text of the chart.'
Dim strSearch As String
Dim strReplace As String

strSearch = "s"  '<-- test that I used, modify as needed.'
strReplace = "##" '<-- test that I used, modify as needed.'

For Each cObj In ActiveSheet.ChartObjects

    Set cht = cObj.Chart
    With cht

        '## Check if the chart has a title, if so, do the replace.'
        If .HasTitle Then
            str = .ChartTitle.Characters.Text
            .ChartTitle = Replace(.ChartTitle, strSearch, strReplace)
        End If

        '## Check if the chart has a legend, if so, do the replace'
        If .HasLegend Then
            For Each legEnt In .Legend.LegendEntries
            str = legEnt.Format.TextFrame2.TextRange.Characters.Text
            legEnt.Format.TextFrame2.TextRange.Characters.Text = _
                Replace(str, strSearch, strReplace)
            Next

        End If


        For Each ax In .Axes
            '## Check if each Axis has a Title, if so, do the replace'
            If ax.HasTitle Then
                str = ax.AxisTitle.Characters.Text
                ax.AxisTitle.Characters.Text = Replace(str, strSearch, strReplace)

            End If

        Next

        '## For each series, do the replace in series.name'
        For Each srs In .SeriesCollection
            str = srs.Name
            srs.Name = Replace(str, strSearch, strReplace)

        Next

    End With
Next

End Sub

Answer 2

这涉及形状，包括文本框，工作表中包含的图表，以及自己工作表上的图表：

Sub ReplaceTextInShapesAndCharts()
Dim ws As Excel.Worksheet
Dim chtObject As Excel.ChartObject
Dim chtChart As Excel.Chart
Dim shp As Excel.Shape

For Each ws In ThisWorkbook.Worksheets
    'textboxes and other shapes
    For Each shp In ws.Shapes
        'charts don't have TextFrames - handled separately
        If Not shp.Type = msoChart Then
            shp.TextFrame.Characters.Text = Replace(shp.TextFrame.Characters.Text, "great", "fantastic")
        End If
    Next shp
    'in-sheet charts
    For Each chtObject In ws.ChartObjects
        ChartTextReplace chtObject.Chart
    Next chtObject
    'charts on their own sheets
    For Each chtChart In ThisWorkbook.Charts
        ChartTextReplace chtChart
    Next chtChart
Next ws
End Sub

Sub ChartTextReplace(chtChart As Excel.Chart)
Dim shp As Excel.Shape

With chtChart
    'textboxes in chart
    For Each shp In .Shapes
        shp.TextFrame.Characters.Text = Replace(shp.TextFrame.Characters.Text, "great", "fantastic")
    Next shp
    'expand this section as needed
    .ChartTitle.Text = Replace(.ChartTitle.Text, "great", "fantastic")
End With
End Sub

使用vba迭代Excel中的所有文本（单元格，图表，文本框）

2 个答案: