更新

Question

好吧，我有一个只采用数字的编辑（没有字母，没有符号，只有数字）。问题是我不希望用户将0作为第一个数字，例如（0239847）。

我在考虑制作变量“x” - ＆gt;字节，它将计算编辑的长度并删除第一个数字，如果它是0：

var l:length; number:string100;
begin
l:length(edit1.text);

现在，如果第一个数字是0（0239847），则删除它，但如果没有其他数字（仅为0），则保持原样。

Omg，我终于找到了最简单的方法：

procedure TForm1.Edit1Change(Sender: TObject);
var digit1:string;
begin
digit1:=edit1.Text;
if (digit1='00') or (digit1='01') or (digit1='02') or (digit1='03') or (digit1='04') or
(digit1='05') or (digit1='06') or (digit1='07') or (digit1='08') or (digit1='09') then
edit1.Text:=clear;    //or edit1.text:=0;  it's the same

end;

end.

仍然可以复制和粘贴数字，但我不介意

这是一个非常愚蠢的问题，因为答案很容易而且显而易见，但如果你太累了，很难找到它，我很抱歉让你为此忙，Andreas，谢谢你的帮助和提示。

Answer 1

很难做到这一点。最雄心勃勃的方法是在密钥关闭，粘贴等方面做很多逻辑，就像在this answer中一样。你会惊讶地发现有多少案件需要处理！

这很好用，我想：

type
  TEdit = class(StdCtrls.TEdit)

...

procedure TEdit.KeyPress(var Key: Char);

  function InvalidKey: boolean;
  begin
     InvalidKey :=
       (
         (Key = '0') and
           (
             ((SelStart = 0) and (Length(Text) - SelLength <> 0))
             or
             ((SelStart = 1) and (Text[1] = '0'))
           )
       )
       or
       (
         not (Key in ['0'..'9', #8, ^Z, ^X, ^C, ^V])
       )
  end;

begin
  inherited;

  if InvalidKey then
  begin
    beep;
    Key := #0;
  end else if (SelStart = 1) and (Text[1] = '0') then
  begin
    Text := Copy(Text, 2);
  end;
end;

procedure TEdit.WMPaste(var Message: TWMPaste);    
var
  ClipbrdText: string;

  function ValidText: boolean;
  var
    i: Integer;
  begin
    result := true;
    for i := 1 to Length(ClipbrdText) do
      if not (ClipbrdText[i] in ['0'..'9']) then
      begin
        result := false;
        break;
      end;
  end;

  function RemoveLeadingZeros(const S: string): string;
  var
    NumLeadingZeros: integer;
    i: Integer;
  begin
    NumLeadingZeros := 0;
    for i := 1 to Length(S) do
      if S[i] = '0' then
        inc(NumLeadingZeros)
      else
        break;
    result := Copy(S, NumLeadingZeros + 1);
  end;

begin
  if Clipboard.HasFormat(CF_TEXT) then
  begin

    ClipbrdText := Clipboard.AsText;

    if not ValidText then
    begin
      beep;
      Exit;
    end;

    if SelStart = 0 then
      ClipbrdText := RemoveLeadingZeros(ClipbrdText);

    SelText := ClipbrdText;

  end
  else
    inherited;
end;

这看起来很复杂，但所有这些逻辑都是必要的。例如，代码可以很好地处理所有这些情况：

您只能输入数字。
如果选择了SelStart = 0和并非每个字符，则无法输入0，因为这样您就会获得前导零。
如果选择了SelStart = 0和每个字符，则可以输入0。因为您应该能够输入此有效数字。
- 特殊情况：如果字符为零，那么当然会选择零字符，因此只需逻辑，就可以从空字符串的状态输入0 ！
如果SelStart = 1和Text[1] = '0' [if SelStart = 1，那么Text[1]存在，那么我们依靠这里的布尔短路评估]，那你就不能输入0。
如果编辑字段的内容为0，并且您在零之后添加非零字符，则删除零（并且不会干扰插入符号位置）。
您只能粘贴数字。如果SelStart = 0，前导零（在剪贴板数据中）将被丢弃。

事实上，为了使行为更加完美，您需要更多代码。例如，假设编辑字段的内容为123000456。就像现在一样，您可以选择前三个字符（123）并按 Backspace 或删除以获取无效文本000456。解决方案是添加额外的代码，删除由这两个操作中的任何一个产生的前导零。 更新：我一直在思考，并且已经意识到实现这个可能最好不（为什么？）。

然而，一个捷径就是在没有聚焦的情况下对编辑内容进行“美化”，因为当它没有聚焦时，你不太可能通过做一些事情来拍摄用户。编辑内容。

例如，您可以执行类似

的操作

function PrettifyNumber(const S: string): string;
var
  NumLeadingZeros: integer;
  i: Integer;
begin
  NumLeadingZeros := 0;
  for i := 1 to Length(S) do
    if S[i] = '0' then
      inc(NumLeadingZeros)
    else
      break;
  result := Copy(S, NumLeadingZeros + 1);
  if length(result) = 0 then
    result := S;
end;

然后当它失去键盘焦点时，用其美化版本替换编辑字段的内容。当然，您应该考虑将此功能添加到派生的编辑类中，但是为了进行测试，您只需使用OnExit事件：

procedure TForm1.Edit1Exit(Sender: TObject);
begin
  Edit1.Text := PrettifyNumber(Edit1.Text);
end;

我认为您希望在主要应用程序（或不是那么重要）中进行大量编辑时使用此功能。所以你实际上会编写自己的子类控件。那么我想你还需要其他类型的验证，而不仅仅是删除前导零？因此，您必须将此代码与其余代码很好地集成。如果实际上你将在一个大型应用程序中的任何地方使用这个编辑“子类”，你也可以考虑在编辑控件类中添加一个快捷方式，这样你就可以根据需要对文本进行美化/验证，而不仅仅是在退出时（如果编辑控件单独在其表单上，则特别困难！）

更新

根据要求，这是一个非常有效的简单解决方案：

procedure TForm1.Edit1KeyPress(Sender: TObject; var Key: Char);
begin
  if (Key = '0') and (Edit1.SelStart = 0) then Key := #0;
end;

我将其作为练习来解决这种方法的问题。如果你一个接一个地解决问题，当你发现它们时，你最终会得到我的长代码！

Answer 2

您可以使用TmaskEdit。这迫使用户输入数字。添加eventchange以删除第一个数字，如果为0.

Example.dfm

.
.
object MaskEdit1: TMaskEdit
  Left = 352
   Top = 8
   Width = 120
   Height = 21
   EditMask = '0999999;0;_'
   MaxLength = 7
   TabOrder = 3
   OnChange = MaskEdit1Change
end
.
.

Example.pas

.
.
Procedure TForm1.MaskEdit1Change(Sender: TObject);
Begin
  If Length(TMaskEdit(Sender).Text) > 1 Then
    TMaskEdit(Sender).Text := IntToStr(StrToInt(TMaskEdit(Sender).Text));
End;
.
.

如何使编辑控件不接受0作为第一个数字？

2 个答案:

更新