Question

我需要将两个XML文件与XSLT合并。它们看起来像这样：

<xml xmlns:s='uuid:BDC6E3F0-6DA3-11d1-A2A3-00AA00C14882'
    xmlns:dt='uuid:C2F41010-65B3-11d1-A29F-00AA00C14882'
xmlns:rs='urn:schemas-microsoft-com:rowset'
xmlns:z='#RowsetSchema'>
<s:Schema id='RowsetSchema'>
    ... Some stuff
</s:Schema>
<rs:data>
  <z:row Initialer='HBL' personaleGrupper='FF' Fornavn='Harald' Efternavn='Blåtand'     personnummer='123459'/>
</rs:data>
</xml>

另一个文件看起来像：

<rs:data>
  <z:row Initialer='KT' personaleGrupper='FF' Fornavn='Kristian' Efternavn='Tyrann' personnummer='546578'/>
</rs:data>

我的尝试是：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
            xmlns:rs="urn:schemas-microsoft-com:rowset"
            xmlns:z="#RowsetSchema">

<xsl:template match="rs:data">
<xsl:copy>
    <xsl:apply-templates select="@* | node() | document('doc2.xml')/rs:data/z:row/node()" />
</xsl:copy>
</xsl:template>

<xsl:template match="node() | @*">
    <xsl:copy-of select="." />
</xsl:template>

</xsl:stylesheet>

但是，我几乎得到了源文件（doc1.xml）的副本。换句话说，架构部分就在那里，而HaraldBlåtand的一个rs：data行就在那里。但不是Kristian Tyrann系列。

我做错了什么？

Answer 1

我不完全确定你的输出应该是什么样的。

以下xslt将从第一个文档中rs：data条目后面的doc2.xml复制rs：data条目。

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
            xmlns:rs="urn:schemas-microsoft-com:rowset"
            xmlns:z="#RowsetSchema">

    <xsl:template match="xml">
        <xsl:copy>
            <xsl:apply-templates select="@* | node() " />
            <xsl:apply-templates select="rs:data"  mode="copy" />
            <xsl:apply-templates select="document('doc2.xml')//rs:data" mode="copy" />
        </xsl:copy>
    </xsl:template>

    <xsl:template match="rs:data" />

    <xsl:template match="*" mode ="copy">
        <xsl:copy>
            <xsl:apply-templates select="@* | node() " />
        </xsl:copy>
    </xsl:template>

    <xsl:template match="node() | @*">
        <xsl:copy>
            <xsl:apply-templates select="@* | node() " />
        </xsl:copy>
    </xsl:template>

</xsl:stylesheet>

并生成以下输出：

?xml version="1.0"?>
<xml xmlns:s="uuid:BDC6E3F0-6DA3-11d1-A2A3-00AA00C14882" xmlns:dt="uuid:C2F41010-65B3-11d1-A29F-00AA00C14882" xmlns:rs="urn:schemas-microsoft-com:rowset" xmlns:z="#RowsetSchema">
    <s:Schema id="RowsetSchema">
        ... Some stuff
    </s:Schema>

    <rs:data>
        <z:row Initialer="HBL" personaleGrupper="FF" Fornavn="Harald" Efternavn="Bl&#xE5;tand" personnummer="123459"/>
    </rs:data>
    <rs:data>
        <z:row Initialer="KT" personaleGrupper="FF" Fornavn="Kristian" Efternavn="Tyrann" personnummer="546578"/>
    </rs:data>
</xml>

<强>更新似乎输出中只应该有一个rs：data并且只合并z：row。试试这个：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
            xmlns:rs="urn:schemas-microsoft-com:rowset"
            xmlns:z="#RowsetSchema">

    <xsl:template match="xml">
        <xsl:copy>
            <xsl:apply-templates select="@* | node() " />
        </xsl:copy>
    </xsl:template>

    <xsl:template match="rs:data" >
        <xsl:copy>
            <xsl:apply-templates select="@* | node() " />
            <xsl:apply-templates select="document('doc2.xml')//rs:data/*" />
        </xsl:copy>
    </xsl:template>

    <xsl:template match="node() | @*">
        <xsl:copy>
            <xsl:apply-templates select="@* | node() " />
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

生成：

<xml xmlns:s="uuid:BDC6E3F0-6DA3-11d1-A2A3-00AA00C14882" xmlns:dt="uuid:C2F41010-65B3-11d1-A29F-00AA00C14882" xmlns:rs="urn:schemas-microsoft-com:rowset" xmlns:z="#RowsetSchema">
    <s:Schema id="RowsetSchema">
        ... Some stuff
    </s:Schema>
    <rs:data>
        <z:row Initialer="HBL" personaleGrupper="FF" Fornavn="Harald" Efternavn="Bl&#xE5;tand" personnummer="123459"/>
        <z:row Initialer="KT" personaleGrupper="FF" Fornavn="Kristian" Efternavn="Tyrann" personnummer="546578"/>
    </rs:data>
</xml>

将两个XML文件与XSLT结合使用

1 个答案: