Question

我遇到以下情况：我有一个列表，我只想从中删除最后一个元素。

我已实施以下规则（效果不佳）：

deleteLastElement([Only],WithoutLast) :-
    !,
    delete([Only],Only,WithoutLast).
deleteLastElement([_|Tail],WithoutLast) :-
    !,
    deleteLastElement(Tail,WithoutLast).

问题在于，当我调用它时，列表中的所有元素都被删除，实际上如果我执行以下语句，我会得到：

[debug]  ?- deleteLastElement([a,b,c], List).
List = [].

查看跟踪我认为这个问题的原因很清楚：

[trace]  ?- deleteLastElement([a,b], List).
   Call: (7) deleteLastElement([a, b], _G396) ? creep
   Call: (8) deleteLastElement([b], _G396) ? creep
   Call: (9) lists:delete([b], b, _G396) ? creep
   Exit: (9) lists:delete([b], b, []) ? creep
   Exit: (8) deleteLastElement([b], []) ? creep
   Exit: (7) deleteLastElement([a, b], []) ? creep
List = [].

当达到基本案例时，不再列出列表与空列表 []统一，当执行回溯时，不再列出仍然仍然是空名单。

这不好。

我正在考虑执行以下操作：

在调用删除最后一个元素的谓词之前，计算列表中元素的数量。
通过递归迭代并每次递减元素数量的值
如果元素的数量为0，则表示这是最后一个元素，因此我将其从原始列表中删除

但在我看来，这似乎并不清楚，并且不太好，我会知道是否有一个声明性良好的解决方案来解决这个问题。

Answer 1

我觉得你的分析有点过于复杂。让我们从基本案例开始：

without_last([_], []).

当你在最后一个元素时，结果应该是空列表。

因此，归纳案件必须是我们不在最后一个要素的情况。在我有一些元素附加到任意长列表的情况下，没有最后一个元素的列表只是列表的尾部，没有最后一个元素，前面有当前元素。或者：

without_last([X|Xs], [X|WithoutLast]) :- 
    without_last(Xs, WithoutLast).

这适用于各个方向。

?- without_last([1,2,3,4], X).
X = [1, 2, 3] ;
false.

?- without_last([1,2], X).
X = [1] .

?- without_last([1], X).
X = [] ;
false.

?- without_last([], X).
false.

?- without_last(X, [1,2,3]).
X = [1, 2, 3, _G294].

?- without_last([1,2,3,4], [1,2,3]).
true.

?- without_last([1,2,3,X], [1,2,3]).
true.

Answer 2

如果您开发了一个递归过程，该过程遍历输入列表的每个元素，当您找到最后一个元素将结果列表与空列表统一时，您的基本案例将停止。然后，从递归调用返回，您只需将所有其他项添加到结果列表中：

不使用剪切：

deleteLastElement([_], []).
deleteLastElement([Head, Next|Tail], [Head|NTail]):-
  deleteLastElement([Next|Tail], NTail).

当第一个参数列表中只有一个元素时，第一个子句（基本情况）将第二个参数与空列表统一起来。

第二个子句指出当第一个参数是一个至少包含两个元素的列表时，你递归调用自身（没有头部），将Head添加到该调用返回的第二个参数。

事实上，你不需要在第二个条款中明确表明列表需要至少有两个元素，

deleteLastElement([Head|Tail], [Head|NTail]):-
  deleteLastElement(Tail, NTail).

当然，您也可以使用append/3删除列表中的最后一项：

append(WithoutLast, [_], List).

Answer 3

@ repeat的实现肯定是当前Prolog处理器中最有效的实现，我仍然喜欢将DCG用于此目的 - 暗地希望有一天实现技术能够以相当的（空间）运行它效率

list_butlast(Xs, Ys) :-
   phrase( ( seq(Ys), [_] ), Xs).

seq([]) -->
   [].
seq([E|Es]) -->
   [E],
   seq(Es).

Answer 4

从列表中删除最后一个元素的最简单方法是：

反转列表
现在删除第一个元素
反转剩余的列表

你应该使用的代码：

delete_last(X,Y):-
    reverse(X,[_|X1]), reverse(X1,Y).

Answer 5

这是一个老问题，但我发现了另外两种方法：

不要创建无用的选择点。
不需要额外的谓词。

findall(X ,append(X, [_], List), [X]).

length(List, N), nth1(N, List, _, X).

如何从Prolog中的列表中删除最后一个元素？

5 个答案: