Question

我正在写作业（CIS194 Haskell课程）。

我必须将以下递归函数重写为管道函数（没有明显的递归）。

fun2 :: Integer -> Integer
fun2 1 = 0
fun2 n 
    | even n = n + fun2 ( n ‘div‘ 2 )
    | otherwise = fun2 (3 * n + 1)

我的第一次尝试就在这里：

fun2''' = sum 
          . (filter (even)) 
          . unfoldr (\x -> if (even x) 
                          then Just (x, x `div` 2)
                          else if (x==1) then Nothing 
                               else Just (x, x * 3 + 1))

这是正常的解决方案还是很奇怪？

我怎样才能更好地重写fun2？

现在我尝试使用takeWhile和iterate

编写版本

我的第二次尝试：

fun2'' :: Integer -> Integer
fun2'' = sum 
         . (filter even) 
         . takeWhile (/=1) 
         . iterate (\x -> if even x 
                          then x `div` 2
                          else x * 3 + 1 )

我现在对until版本几乎没有任何问题。

Answer 1

看起来不错，Haskell中唯一有点红旗的是else if。在这种情况下，它可以在应用风格中很好地重写：

{-# LANGUAGE TupleSections     #-}

import Control.Applicative
import Control.Monad (guard)

fun2''' = sum 
          . filter even
          . unfoldr ( \x -> fmap (x,) $
                   x`div`2 <$ guard(even x)
               <|> x*3 + 1 <$ guard( x/=1 )
             )

Answer 2

嵌套if现在可以使用multi-way IF编写：

g :: Integer -> Integer
g = sum . 
     unfoldr (\x-> 
          if | even x    -> Just (x, x `div` 2) 
             | x==1      -> Nothing 
             | otherwise -> Just (0, x * 3 + 1))

或者您可以定义自己的 if 运算符，

(??) t (c,a) | t = c | otherwise = a

g = sum . unfoldr (\x-> even x ?? (Just (x, x `div` 2) ,
                        (x==1) ??  (Nothing, Just (0, x * 3 + 1))))

与until功能相同，sum和filter融合在一起：

g = fst . until ((==1).snd) 
            (\(s,n) -> if even n then (s+n,n`div`2) else (s,3*n+1)) 
    . ((,)0)

或

g = sum . filter even . f

f :: Integer -> [Integer]
f = (1:) . fst . until ((==1).snd) 
            (\(s,n) -> if even n then (n:s,n`div`2) else (n:s,3*n+1)) 
    . ((,)[])

最后一个函数f显示给定输入数字的整个Collatz序列，反转。

将递归函数重写为管道函数组合

2 个答案: