Question

标题并没有说很多东西，所以让我解释一下：

我已经制作了一个申请表，其中我放了1张图片和4个按钮。每当我按下按键：向上，向下，向左，向右移动图像时，它会选择按钮，保证移动图像。例如，如果我按下向下键，它会选择我按钮2，如果我按下它，它会选择我按钮1 ....

我很吵，我无法真实地描述它的样子，在你的表格中尝试它，你会看到我的意思，代码就是这样：

procedure TForm1.FormKeyDown(Sender: TObject; var Key: Word;
  Shift: TShiftState);
begin
  case Key of
    VK_UP:
      image1.Top := image1.Top - 10;
    VK_DOWN:
      image1.Top := image1.Top + 10;
    VK_LEFT:
      image1.Left := image1.Left - 10;
    VK_RIGHT:
      image1.Left := image1.Left + 10;
   end;
end;

Answer 1

最佳解决方案是将控件（图像）放入处理对话框键的窗口（控件）中，然后确保此控件在适当的时间接收键盘焦点。

老实说，你似乎通过移动图形控件来绘制/动画。非常最好的方法是创建一个自定义控件（从TCustomControl下降）并手动绘制内容（或者，可能有图形子控件）。然后，您可以轻松地使此控件响应箭头键。

此控件执行此操作：

unit WindowContainer;

interface

uses
  SysUtils, Windows, Messages, Classes, Controls;

type
  TWindowContainer = class(TCustomControl)
  private
  protected
    procedure WMGetDlgCode(var Message: TWMGetDlgCode); message WM_GETDLGCODE;
  public
    constructor Create(AOwner: TComponent); override;
  published
    property OnStartDrag;
    property OnStartDock;
    property OnUnDock;
    property OnClick;
    property OnCanResize;
    property OnAlignPosition;
    property OnAlignInsertBefore;
    property OnResize;
    property OnMouseWheel;
    property OnMouseWheelDown;
    property OnMouseWheelUp;
    property OnMouseUp;
    property OnMouseMove;
    property OnMouseLeave;
    property OnMouseEnter;
    property OnMouseDown;
    property OnMouseActivate;
    property OnKeyUp;
    property OnKeyPress;
    property OnKeyDown;
  end;

procedure Register;

implementation

procedure Register;
begin
  RegisterComponents('Rejbrand 2009', [TWindowContainer]);
end;

{ TWindowContainer }

constructor TWindowContainer.Create(AOwner: TComponent);
begin
  inherited;
  ControlStyle := [csAcceptsControls, csCaptureMouse, csClickEvents,
    csSetCaption, csDoubleClicks, csReplicatable, csPannable,
    csFramed];
end;

procedure TWindowContainer.WMGetDlgCode(var Message: TWMGetDlgCode);
begin
  inherited;
  Message.Result := Message.Result or DLGC_WANTCHARS or DLGC_WANTARROWS
    or DLGC_WANTTAB or DLGC_WANTALLKEYS;
end;

end.

Screenshot http://privat.rejbrand.se/WindowContainerSample.png

Sample demo EXE

要尝试此控件，只需将形状/图像放入其中，然后使用此控件的OnKeyDown事件。此外，请务必将焦点设置为此控件，例如当用户点击它时：

procedure TForm1.WindowContainer1Click(Sender: TObject);
begin
  WindowContainer1.SetFocus;
end;

现在，通过移动控件来制作动画很糟糕。相反，你应该手动绘制。将此答案与this答案中的代码相结合，您就完成了。

Delphi7，由于按钮，我无法使用UP，DOWN，LEFT，RIGHT键移动图像

1 个答案: