Question

我想编写一个整数和一个数字列表的谓词，如果Digits包含正确顺序的整数数字，则成功，即：

?-digit_lists( Num, [1,2,3,4] ).
[Num == 1234].

这是我到目前为止所做的：

my_digits( 0, [] ).
my_digits(N,[A|As]) :- N1 is floor(N/10), A is N mod 10, my_digits(N1, As).

Answer 1

如前所述，请考虑使用有限域约束：

:- use_module(library(clpfd)).

number_digits(Number, 0, [Number]) :- Number in 0..9.
number_digits(Number, N, [Digit|Digits]) :-
        Digit in 0..9,
        N #= N1 + 1,
        Number #= Digit*10^N + Number1,
        Number1 #>= 0,
        N #> 0,
        number_digits(Number1, N1, Digits).

此谓词可用于所有方向。实例化任一参数的示例：

?- number_digits(215, _, Ds).
Ds = [2, 1, 5] ;
false.

?- number_digits(N, _, [4,3,2,1]).
N = 4321 ;
false.

另外两个一般性问题：

?- number_digits(N, _, [A,B]).
N in 10..99,
_G2018+B#=N,
_G2018 in 10..90,
A*10#=_G2018,
A in 0..9,
B in 0..9 ;
false.

?- number_digits(N, _, Ds).
Ds = [N],
N in 0..9 ;
Ds = [_G843, _G846],
N in 0..99,
_G870+_G846#=N,
_G870 in 0..90,
_G843*10#=_G870,
_G843 in 0..9,
_G846 in 0..9 ;
etc.

Answer 2

以下是另一种基于clpfd的变体...基于(#=)/3和 if_//3 我们定义：

n_base_digits(N, R, Ds) :-
   N #> 0,                                  % positive integers only
   R #> 1,                                  % smallest base = 2
   Ds = [D|_],                              % leading digit may not be 0
   D #> 0,
   phrase(n_base_digits_aux(N, R, Ds), Ds).

n_base_digits_aux(N, Base, [_|Rs]) -->
   { D #= N mod Base,
     M #= N // Base },
   if_(M #= 0,
       { Rs = [] },
       n_base_digits_aux(M, Base, Rs)),
   [D].

使用SICStus Prolog 4.3.3查询：

| ?- n_base_digits(1234, 10, Ds).
Ds = [1,2,3,4] ? ;
no

反过来也是如此！

| ?- n_base_digits(I,10,[1,2,3]).
I = 123 ? ;
no

请注意，上述内容比建议by @mat in his answer的number_digits/3快。

Answer 3

您还可以避免递归并使用内置谓词进行类型转换：

my_digits(Number, List) :-
    atomic_list_concat(List, Atom),
    atom_number(Atom, Number).

第一行将列表转换为原子，第二行将此原子转换为数字，如果该数字与传入的数字相同，则该数字为真。

我不知道是否有更直接的方式将列表转换为数字（不要这么认为..），在这种情况下，它可以在一行中实现。

Answer 4

我不同意@ssBarBee。毕竟，如果你提供你的清单并且他们的指控是正确的，你应该得到4321;但你得到这个：

?- my_digits(Num, [1,2,3,4]).
ERROR: is/2: Arguments are not sufficiently instantiated

我们可以使用clpfd：

进行尝试

my_digits( 0, [] ).
my_digits(N,[A|As]) :- N1 #= N/10, A #= N mod 10, my_digits(N1, As).

我们得到了这个：

?- my_digits(Num, [1,2,3,4]), label([Num]).
Num = -6789 ;
Num = 4321.

我发现所有这些都很好奇，但用clpfd进行追踪并不令人愉快。

如果你只是想解析一个数字列表，我会倾向于使它像往常一样递归：

my_digits(Num, List) :- my_digits(0, List, Num).

my_digits(Num, [], Num).
my_digits(N, [A|As], Num) :- N1 is N * 10 + A, my_digits(N1, As, Num).

这给了我们：

?- my_digits(Num, [1,2,3,4]).
Num = 1234 ;
false.

但它不会产生：

?- my_digits(1234, X).
ERROR: is/2: Arguments are not sufficiently instantiated

如果我在没有clpfd的情况下解决这个问题，那么我现在倾向于只检查我的论点并使用单独的谓词。我知道Gross，但这就是我要做的事。

my_digits(Num, List) :- 
    nonvar(List), 
    my_digits_p(0, List, Num).
my_digits(Num, List) :- 
    var(List), 
    my_digits_g(Num, ListRev), 
    reverse(ListRev, List).

my_digits_p(Num, [], Num).
my_digits_p(N, [A|As], Num) :- N1 is N * 10 + A, my_digits(N1, As, Num).

my_digits_g(0, []) :- !.
my_digits_g(N, [A|As]) :- A is N mod 10, N1 is floor(N / 10), my_digits_g(N1, As).

这可以解析或检查，或者生成数字是否为非变量：

?- my_digits(1234, X).
X = [1, 2, 3, 4].

?- my_digits(X, [1,2,3,4]).
X = 1234 ;
false.

?- my_digits(1234, [1,2,3,4]).
true;
false.

如果你尝试使用两个参数作为变量生成，你会得到一个非常无益的结果：

?- my_digits(X, Y).
X = 0,
Y = [].

因此，我们可以通过向my_digits添加另一个特殊情况来尝试生成：

my_digits(Num, List) :- 
    var(Num), var(List), 
    my_digits_g_from(0, Num, ListRev), 
    reverse(ListRev, List).
my_digits(Num, List) :- 
    nonvar(List), 
    my_digits_p(0, List, Num).
my_digits(Num, List) :- 
    var(List), 
    my_digits_g(Num, ListRev),
    reverse(ListRev, List).

my_digits_g_from(N, N, List)   :- my_digits_g(N, List).
my_digits_g_from(N, Num, List) :- succ(N, N1), my_digits_g_from(N1, Num, List).

这是很多代码，并且很好地证明了在不使用clp(fd)时必须要做的杂技。这是一个不幸的事实，当在Prolog中进行算术时，必须解决is不统一的事实，但clp(fd)的复杂性很好地证明了为什么会这样。

我希望其他人有一个更优雅的解决方案！

Answer 5

课程作业？教授可能正在寻找的是以下内容。一般规则，您对问题陈述的分析应首先确定特殊情况（在这种情况下，零和负值），然后是一般情况。

: -- int_2_digits/2 ------------------------------------------------------------
: 
: The public api.
:
: we've got 2 special cases here:
: 
: * zero, and
: * negative numbers
:
: and, of course, the general case: a positive value.
:
: ------------------------------------------------------------------------------
int_2_digits( 0 , [0] ) .       : zero is a special case
int_2 digits( X , ['-'|Ds] ) :- : negative numbers are a special case
  X < 0 ,                       :   which we handle (YMMV) by prepending the
  X1 is - X ,                   :   sign and than processing the absolute value
  int_2_digits(X1,Ds) .         :
int_2_digits( X , Ds       ) :- : the general case is a positive value
  X > 0 ,                       : just invoke the worker predicate.
  int_2_digits(X,[],Ds) .       :

: -- int_2_digits/3 ------------------------------------------------------------
: 
: The guts of the operation.
: 
: We're using an accumulator here because we compute the result right-to-left,
: from least significant digit to most significant digit. Using the accumulator
: builds the list in the correst sequence, so we don't have to reverse it at
: the end.
: ------------------------------------------------------------------------------
int_2_digits( 0 , Ds , Ds ) .      : if we hit zero, we're done. Unify the accumulator with the result
int_2_digits( X , Ts  , Ds ) :-    : otherwise...
  D is mod(X,10) ,                 : - get the current digit (X modulo 10)
  T is div(X,10) ,                 : - get the next value via integer division
  int_2_digits( X1 , [T|Ts] , Ds ) : - recurse down
  .                                : Easy!

Answer 6

我认为这更容易：

numToList(NUM,[LIST|[]]):-
   NUM < 10,
   LIST is NUM,
   !.
numToList(NUM,LIST):-
   P is NUM // 10,
   numToList(P,LIST1),
   END is (NUM mod 10), 
   append(LIST1,[END] ,LIST).

Prolog将整数转换为数字列表

6 个答案: