Question

AQ $ _MESSAGES_EXCEPTION首先我知道有这个问题：How to clear a queue in Oracle AQ但它没有答案。

我在Oracle AQ的异常队列中有很多消息（500k）（我不知道过期的消息被移动到另一个队列，所以我没有为那些创建消费者）。我现在需要的是能够快速删除这些消息。我已经读过通过删除清除队列表不是一个好主意，因为它可能导致状态不一致。所以我把以下程序放在一起，但它只清除 50条消息/秒

EXECUTE dbms_aqadm.start_queue(queue_name => 'AQ$_MESSAGES_EXCEPTION', 
                               enqueue => FALSE, dequeue => TRUE);

DECLARE
   dequeue_options     DBMS_AQ.dequeue_options_t;
   message_properties  DBMS_AQ.message_properties_t;
   message_handle      RAW(16);
   message             SYS.AQ$_JMS_MESSAGE;
   no_messages         EXCEPTION;
   pragma exception_init (no_messages, -25228);
BEGIN
   dequeue_options.wait := DBMS_AQ.NO_WAIT;
   dequeue_options.navigation := DBMS_AQ.FIRST_MESSAGE;
   LOOP
   DBMS_AQ.DEQUEUE(
      queue_name          =>     'AQ$_MESSAGES_EXCEPTION',
      dequeue_options     =>     dequeue_options,
      message_properties  =>     message_properties,
      payload             =>     message,
      msgid               =>     message_handle);
  DBMS_OUTPUT.put_line ('Message: ' || message_handle || ' dequeued');
  END LOOP;
  EXCEPTION
    WHEN no_messages THEN
      DBMS_OUTPUT.put_line (' ---- NO MORE MESSAGES  ---- ');
    WHEN others then
      DBMS_OUTPUT.put_line ('Exception queue not started for dequeue.');
END;

/

考虑到它在数据库机器上运行，看起来真的很慢。使用500k消息，此过程大约需要三个小时。 我能以更有效的方式进行吗？

编辑：

我在此处的链接中尝试了dequeue_array：http://www.oracle-developer.net/display.php?id=319 但我无法创建表，所以我正在尝试创建一个数组来“存储”结果。这就是我所拥有的：

DECLARE
    type messages_type  is varray(500) of SYS.AQ$_JMS_MESSAGE;
    messages            messages_type;
    dequeue_options     DBMS_AQ.dequeue_options_t;
    msg_properties      DBMS_AQ.message_properties_array_t;
    msg_ids             DBMS_AQ.MSGID_ARRAY_T;
    x_timeout           EXCEPTION;
    no_messages         EXCEPTION;
    dequeue_batch       PLS_INTEGER := 500;
    pragma exception_init (no_messages, -25228);
BEGIN        
    messages := messages_type();
    msg_properties := DBMS_AQ.MESSAGE_PROPERTIES_ARRAY_T();
    msg_properties.EXTEND(dequeue_batch);      
    msg_ids := DBMS_AQ.MSGID_ARRAY_T();   
    dequeue_options.wait := 5;   
LOOP
    DBMS_AQ.DEQUEUE_ARRAY(
    queue_name          =>     'AQ$_MESSAGES_EXCEPTION',
    dequeue_options     =>     dequeue_options,
    array_size          =>     dequeue_batch,
    message_properties_array  =>     msg_properties,
    payload_array             =>     messages,
    msgid_array               =>     msg_ids); 
...

我收到了这个错误：

wrong number or types of arguments in call to 'DEQUEUE_ARRAY'

我认为问题出在messages数组中，但我不知道该怎么做才能使它工作。另外，根据oracle doc（http://docs.oracle.com/cd/B19306_01/appdev.102/b14258/d_aq.htm#i1000850），应该有另一个参数：

error_array               OUT  error_array_t

但是这个参数的解释是“目前没有实现”。这是什么意思？可以省略吗？它应该设置为null吗？这真的令人困惑，谷歌在这里没有帮助:(

Answer 1

如果你真的想要出列，你可以使用dequeue_array（n）函数。那应该快得多。

但您提供的链接确实有解决方案：

-- purge queue
DECLARE
 po_t dbms_aqadm.aq$_purge_options_t;
BEGIN
  dbms_aqadm.purge_queue_table('MY_QUEUE_TABLE', NULL, po_t);
END;

否则，由于此异常队列是自动创建的，我想你可以放弃它，但我不确定这是否安全

BEGIN
  DBMS_AQADM.STOP_QUEUE(
     queue_name => 'demo_queue'
     );
  DBMS_AQADM.DROP_QUEUE(
     queue_name => 'demo_queue'
     );
  DBMS_AQADM.DROP_QUEUE_TABLE(
     queue_table => 'demo_queue_table'
     );
END;

Answer 2

您可以使用程序＆＃34; purge_queue_table＆＃34; （正如@Stephane所说）来自dbms_aqadm包但是使用＆＃34; purge_condition＆＃34;指定参数，使用此参数可以选择要删除的邮件：

示例：

declare

    purge_options dbms_aqadm.aq$_purge_options_t;

begin

      purge_options.block := false;

      purge_options.delivery_mode := dbms_aqadm.persistent;

      dbms_aqadm.purge_queue_table
         (queue_table     => 'vista.svig_std_tab',
          purge_condition => 'qtview.queue = ''AQ$_SVIG_STD_TAB_E'' and qtview.enq_time < to_date(''01.06.2014 00:00:00'',''dd.mm.yyyy hh24:mi:ss'') ',
          purge_options   => purge_options
         );

end;
/

此示例删除来自指定异常队列且早于指定日期的消息。它也比使用＆＃34; dbms_aq.dequeue＆＃34;更快。过程

有没有快速的方法从Oracle AQ清除异常队列？

2 个答案: