Question

我通过解码JSON数据得到了这个输出。

现在我想要反转这个数据结构并使用Perl打印它。

任何人都可以帮我处理下面的代码段吗？

我将这些数据放在一个变量中并打印出来。我的输出如下所示

我有一个哈希哈希，看起来像这样：

$VAR1 = {
    'Packet Loss to Source' => {
        '142' => {
            '161' => '0.000',
            '162' => '0.000',
            '141' => '0.000'
        }
    },
    'Packet Loss to Destination' => {
        '142' => {
            '161' => '0.000',
            '162' => '0.000',
            '141' => '0.000'
        }
    },
    'Average Jitter to Source' => {
        '142' => {
            '161' => '13.323',
            '162' => '37.003',
            '141' => '192.309'
        }
    },
    'Availability' => {
        '142' => {
            '161' => '0.000',
            '162' => '0.000',
            '141' => '1.042'
        }
    },
    'Average Round Trip Time' => {
        '142' => {
            '161' => '772.278',
            '162' => '389.566',
            '141' => '8557.511'
        }
    },
    'Average Jitter to Destination' => {

        '142' => {
            '161' => '13.323',
            '162' => '37.003',
            '141' => '192.309'
        }
    }
};

这是我试图获得输出的代码。我读取了文本文件并获取了JSON数据，解码并打印出来。我在变量$perl_obj中得到了上面的输出。

#my $dirname = "/home/brix/ravikiran/doc/demo.txt";
my $dirname = "/home/brix/ravikiran/doc/JSONData.txt";

open HANDLE, $dirname;
my @raw_data = <HANDLE>;
my $json_text;
foreach my $row (@raw_data) {
    $json_text .= $row;
}
close(HANDLE);

print "$json_text;\n";
my $json = JSON::XS->new();
$json = json->pretty(1)->
    space_before(1)->
    space_after(1)->
    canonical(1)->
    allow_blessed(1)->
    convert_blessed(1);

my $perl_obj = $json->decode($json_text);
print STDOUT Dumper($perl_obj);

Answer 1

您可能不希望reverse任何哈希值（至少在Perl使用该关键字的意义上），因为这涉及交换键和值。您可能想要做的是更改多级哈希中键的顺序。

以下是交换外层两层的方法：

use warnings;
use strict;

my $new_obj;
foreach my $outer_key (keys %$perl_obj)
{
    foreach my $inner_key (keys %{$perl_obj->{$outer_key}})
    {
        $new_obj->{$inner_key}->{$outer_key} = 
            $perl_obj->{$outer_key}->{$inner_key};  
    }
}

use Data::Dumper;
print Dumper $new_obj;

输出：

$VAR1 = {
          '142' => {
                     'Packet Loss to Source' => {
                                                  '161' => '0.000',
                                                  '162' => '0.000',
                                                  '141' => '0.000'
                                                },
                     'Packet Loss to Destination' => {
                                                       '161' => '0.000',
                                                       '162' => '0.000',
                                                       '141' => '0.000'
                                                     },
          ...etc...

你可以完全颠倒它：

my $new_obj;
foreach my $outer_key (keys %$perl_obj)
{
    foreach my $inner_key (keys %{$perl_obj->{$outer_key}})
    {
        foreach my $innest_key (keys %{$perl_obj->{$outer_key}->{$inner_key}})
        {
            $new_obj->{$innest_key}->{$inner_key}->{$outer_key} = 
                $perl_obj->{$outer_key}->{$inner_key}->{$innest_key};   
        }
    }
}

use Data::Dumper;
print Dumper $new_obj;

反转哈希中的哈希哈希值

1 个答案: