Question

我正在尝试将xhtml输入转换为javascript输出，我的输入如下：

 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
    "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">

<html xmlns="http://www.w3.org/1999/xhtml">
<head>
 <title>My page</title>
</head>

<body>
  <ul>
    <li><a href="page.html">about page</a></li>

    <li><a href="ipsum.html">ipsum</a></li>

    <li>there is a text right there

      <ul>

        <li><a href="dolor.html">dolor</a></li>

        <li><a href="yeah.html">yeah</a></li>

   </ul>
</ul>
</body>
</html>

我想在单行javascript中生成输出文件以重复使用菜单，如下所示：

var mytree="";
mytree=' <ul><li><a href="page.html">about page</a></li><li><a href="ipsum.html">ipsum</a></li><li>there is a text right there<ul><li><a href="dolor.html">dolor</a></li> <li><a href="yeah.html">yeah/a></li></ul></ul>';

我如何通过xsl转换生成这个？我试过这个：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:html="http://www.w3.org/1999/xhtml"
    exclude-result-prefixes="html"
    version="2.0">
    <xsl:output  media-type="text/xml" method="xml" indent="no" omit-xml-declaration="yes"  ></xsl:output>
    <xsl:strip-space  elements="html:*"/> 
    <xsl:template match="html:html">
    <xsl:text disable-output-escaping="yes">toctree='</xsl:text>
 <xsl:apply-templates select="html:body"/>
    <xsl:text disable-output-escaping="yes">';</xsl:text>        
    </xsl:template>    
    <xsl:template name="copy" match="html:ul| html:li | html:a"  >
        <xsl:element name="{local-name()}"><xsl:for-each select="@*">
                <xsl:attribute name="{local-name()}">
                    <xsl:value-of select="replace(., '\n', '')" />
                </xsl:attribute>
            </xsl:for-each>
            <xsl:apply-templates />
        </xsl:element>
    </xsl:template> 
</xsl:stylesheet>

它对我有用，但总有很多换行符......我需要一行来定义变量mytree。

由于

Answer 1

只需将此模板添加到提供的转化中：

<xsl:template match="text()">
 <xsl:value-of select="normalize-space()"/>
</xsl:template>

完整的转化现在变为：

<xsl:stylesheet version="2.0" id="" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:html="http://www.w3.org/1999/xhtml" exclude-result-prefixes="html">
    <xsl:output  media-type="text/xml" method="xml" indent="no" omit-xml-declaration="yes"/>
    <xsl:strip-space  elements="html:*"/>

    <xsl:template match="html:html">
      <xsl:text disable-output-escaping="yes">toctree='</xsl:text>
      <xsl:apply-templates select="html:body"/>
      <xsl:text disable-output-escaping="yes">';</xsl:text>
    </xsl:template>

    <xsl:template name="copy" match="html:ul| html:li | html:a"  >
        <xsl:element name="{local-name()}">
           <xsl:for-each select="@*">
                <xsl:attribute name="{local-name()}">
                    <xsl:value-of select="replace(., '\n', '')" />
                </xsl:attribute>
            </xsl:for-each>
            <xsl:apply-templates />
        </xsl:element>
    </xsl:template>

    <xsl:template match="text()">
     <xsl:value-of select="normalize-space()"/>
    </xsl:template>
</xsl:stylesheet>

，并在应用于提供的XML文档时：

<html xmlns="http://www.w3.org/1999/xhtml">
<head>
 <title>My page</title>
</head>

<body>
  <ul>
    <li><a href="page.html">about page</a></li>

    <li><a href="ipsum.html">ipsum</a></li>

    <li>there is a text right there

      <ul>

        <li><a href="dolor.html">dolor</a></li>

        <li><a href="yeah.html">yeah</a></li>
      </ul>
    </li>
  </ul>
</body>
</html>

产生了想要的单行结果：

toctree='<ul><li><a href="page.html">about page</a></li><li><a href="ipsum.html">ipsum</a></li><li>there is a text right there<ul><li><a href="dolor.html">dolor</a></li><li><a href="yeah.html">yeah</a></li></ul></li></ul>';

xhtml到javascript输出通过xslt

1 个答案: