Question

我正在尝试撰写代表银行帐户的记录：

-record(account, {  name :: atom(),
                    type :: atom(),
                    balance = 0 :: integer()  }).

我还想将余额限制为>= 0。我该怎么做？

Answer 1

像balance = 0 :: 0 | pos_integer()之类的东西可能会成功。

编辑不确定它是否存在，但non_neg_integer()会更好：

balance = 0 :: non_neg_integer()

Answer 2

如其他人所述，类型规范仅仅是PropEr和Dialyzer等分析工具的输入。如果您需要强制执行不变balance >= 0，则应该封装帐户类型，只有尊重不变量的函数才能访问：

-module(account).

-record(account, { name :: atom(),
                   type :: atom(),
                   balance = 0 :: non_neg_integer() }).

%% Declares a type whose structure should not be visible externally.
-opaque account() :: #account{}.
%% Exports the type, making it available to other modules as 'account:account()'.
-export_type([account/0]).

%% Account constructor. Used by other modules to create accounts.
-spec new(atom(), atom(), non_neg_integer()) -> account().
new(Name, Type, InitialBalance) ->
    A = #account{name=Name, type=Type},
    set_balance(A, InitialBalance).

%% Safe setter - checks the balance invariant
-spec set_balance(account(), non_neg_integer()) -> account().
set_balance(Account, Balance) when is_integer(Balance) andalso Balance >= 0 ->
    Account#account{balance=Balance};
set_balance(_, _) -> error(badarg). % Bad balance

请注意，这类似于具有面向对象语言（如Java或C ++）中的私有字段的类。通过限制对“受信任”构造函数和访问器的访问，强制执行不变量。

此解决方案不提供针对balance字段的恶意修改的保护。另一个模块中的代码完全可以忽略“opaque”类型规范并替换记录中的balance字段（从records are just tuples开始）。

Erlang记录了类型和值限制以及默认值

2 个答案: