将值添加到Access '07 VBA中的多列列表框中

Question

我是Access '07的初学者。我目前正在研究食堂查询系统。在添加/修改项目屏幕中，我有一个组合框，它从表tblSampleData中绘制值，该表包含Item，Rate，QtyAvailable字段。通过单击转移按钮，我将所需的项目从组合（基本上是所有可用项目的列表）转移到列表框（其中包含用户想要的项目）。组合和列表都有列标题。如何在列表框中创建另一个与任何表无关的行，称为Quantity，用户可以在其中输入项目的数量？

将祝贺紧急帮助。 任何其他解决方法都将得到称赞。 另外，如果您不明白，请随时询问有关此问题的任何疑问。

此致 S Sandeep

Answer 1

如果我正确理解您的要求，您需要在表单中添加一个文本框，以便用户在选择项目时指定数量。

[假设]

- ＆GT;表数据：我的[tblSampleData]如下所示：

ID  Item    Rate    QtyAvailable
1   Item1   Rate1   3
2   Item2   Rate2   5

- ＆GT;组合框：组合框的Bound Column为1，即（隐藏）第一列，即[ID]。

- ＆GT;数据绑定：组合框有Row Source（tblSampleData），但没有Control Source。列表框完全没有绑定。

如果您的情况不同，则需要调整示例代码以适应。

[/假设]

我创建了一个第一次打开时看起来像这样的测试表单：

表单背后的VBA代码是：

Option Compare Database
Option Explicit

Private Sub btnTransfer_Click()
Dim cdb As DAO.Database, rst As DAO.Recordset, qtySelected As Long
Set cdb = CurrentDb
Set rst = cdb.OpenRecordset("SELECT * FROM tblSampleData WHERE ID=" & Me.cbxItems.Value, dbOpenSnapshot)
qtySelected = Val(Nz(Me.txtQty.Value, 0))
If qtySelected <= 0 Then
    MsgBox "Please specify a (positive) quantity.", vbExclamation
Else
    If qtySelected <= rst!QtyAvailable Then
        Me.lstSelected.AddItem rst!ID & ";" & rst!Item & ";" & rst!Rate & ";" & qtySelected
    Else
        MsgBox "Quantity selected exceeds quantity available.", vbExclamation
    End If
End If
rst.Close
Set rst = Nothing
Set cdb = Nothing
End Sub

Private Sub Form_Load()
Do While Me.lstSelected.ListCount > 0
    Me.lstSelected.RemoveItem 0
Loop
Me.lstSelected.AddItem ";Item;Rate;QtySelected"
End Sub

用户从组合框中选择项目......

...在文本框中输入数量...

...然后点击“转移”按钮将项目+所选数量移动到列表框中：