Question

我有一个swf文件加载到主电影中。当孩子完成比赛，即到达最后一帧时，我希望将swf卸下。谁能告诉我我可以在这段代码中添加哪些内容？

//start button

start_button_aboriginal.addEventListener(MouseEvent.CLICK, fl_ClickToLoadUnloadSWF_3,false,0,true);

import fl.display.ProLoader;
var fl_ProLoader_3:ProLoader;

var fl_ToLoad_3:Boolean = true;

function fl_ClickToLoadUnloadSWF_3(event:MouseEvent):void
{
//ADDED APR02 START
    fl_ProLoader_3.contentLoaderInfo.addEventListener(Event.INIT, childInitHandler);
    fl_ProLoader_3.load(new URLRequest("myths/myth_aboriginal.swf"));
//ADDED APR02 END

if(fl_ToLoad_3)
{
    fl_ProLoader_3 = new ProLoader();
    fl_ProLoader_3.load(new URLRequest("myths/myth_aboriginal.swf"));
    addChild(fl_ProLoader_3);
    fl_ProLoader_3.x = 114;
    fl_ProLoader_3.y = 41;
}
else
{
removeChild(fl_ProLoader_3);
fl_ProLoader_3.unloadAndStop();
fl_ProLoader_3 = null;
}
// Toggle whether you want to load or unload the SWF
fl_ToLoad_3 = !fl_ToLoad_3;

 }

Answer 1

你可以

1）使用MovieClip类中定义的未记录的addFrameScript函数在子SWF的最后一帧上放置回调。如果您无法控制加载的SWF中的代码，则非常有用。

addFrameScript（）具有以下签名：

addFrameScript(frameNumber, callback); //frameNumber is zero-based (unlike in the Flash authoring suite, here you would enter 0 to refer to the first frame, and 1 for the second.)

在父SWF中，添加以下内容：

function fl_ClickToLoadUnloadSWF_3(event:MouseEvent):void {
    ...
    fl_ProLoader_3.contentLoaderInfo.addEventListener(Event.INIT, childInitHandler);
    fl_ProLoader_3.load(new URLRequest("myths/myth_aboriginal.swf"));
    ...
}

function childInitHandler(event:Event):void {
    MovieClip(fl_ProLoader_3.content).addFrameScript(MovieClip(fl_ProLoader_3.content).totalFrames-1, unloadChild);
}

function unloadChild() {
    fl_ProLoader_3.unloadAndStop();
}

如果您担心addFrameScript会消失 - 请不要。当您将代码放在时间轴上时，所有代码实际上都被编译到文档类中的函数中，并通过addFrameScript添加了框架侦听器。

请记住定义函数 unloadChild（）。

function unloadChild():void {
    fl_ProLoader_3.unloadAndStop();
}

-OR -

2）当你加载的SWF到达最后一帧时，从你加载的SWF中调度一个事件。

在孩子SWF的最后一帧：

this.dispatchEvent(new Event("lastFrameReached"));

在父SWF中，添加以下内容：

fl_ProLoader_3.content.addEventListener("lastFrameReached", unloadChild);

-OR -

3）订阅孩子的ENTER_FRAME事件并检查孩子是否在最后一帧。

在父SWF中，添加以下内容：

fl_ProLoader_3.content.addEventListener(Event.ENTER_FRAME, checkIfEnded);

function checkIfEnded(event:Event):void {
    if (fl_ProLoader_3.content.currentFrame == fl_ProLoader_3.content.totalFrames) {
        unloadChild();
    }
}

我个人更喜欢addFrameScript - 在我看来是一个更清洁的解决方案。回调运行一次，您不必轮询，也不需要修改子SWF。

Answer 2

有很多方法可以解决这个问题，并且已经多次询问过......

也就是说，在没有在子swf上创建事件侦听器的情况下解决此问题的一种方法是定期检查当前帧的子swf。如果它是swf中的最后一个，请调用unload方法。

// once every second, indefinitely.
var tick:Timer = new Timer(1000, 0);
tick.addEventListener(TimerEvent.TIMER, checkSWF);
tick.start();

//Load something to the stage.
var loader:Loader = new Loader();
loader.load(new URLRequest("child.swf")); 
addChild(loader);


function checkSWF(e:Event):void {
    if (loader.content.currentFrame == loader.content.totalFrames) {
        tick.stop(); // stop the timer
        loader.unloadAndStop();
    }
}

当达到最终帧时，外部swf应该卸载

2 个答案: