Question

我正在开发一个项目，其中包括在xml上应用一些xslt。

我的输入xml包含＆＃34; CDATA＆＃34;在任何xml节点中。

现在我想要的是它应该保持＆＃34; CDATA＆＃34;如果它有输入

我尝试过很多解决方案，比如disable-output-escaping和cdata-section-elements等... 但我发现它们都不适合我的要求。

那么，有什么方法可以做到吗？如果输入的xml节点有cdata，那么如果输入xml节点没有cdata那么它应该在输出中给它，那么它不应该在输出中给它。

我有一个调用的节点，其中包含cdata和另一个不包含cdata的差异位置的节点..

<Address>
<Location>
<Code>912</Code>
<Value>10301</Value>
</Location>
<Name><![CDATA[E&S]]></Name>
<CompanyName><![CDATA[E&S]]></CompanyName>
<AddressLine3>dummy address</AddressLine3>
<City>dummy city</City>
<State>dummy state</State>
<PostalCode>dummy postal code</PostalCode>
<Country>dummy country</Country>
</Address>
<Nodes>
<Node>
<Type>CTU</Type>
<Text><![CDATA[dummy text & dummy Text.]]></Text>
</Node>
</Nodes>

不固定的是，只有预定义的节点才能包含cdata，它可以来到任何地方

Answer 1

XSLT使用的XPath数据模型不允许区分任何CDATA部分 - 其中任何部分都表示为文本节点的（部分）。因此，完全通用性无法单独使用XSLT或XPath来实现CDATA保存。它可以通过基于DOM的方法实现。

如果在转换CDATA部分的输出中需要具有特定名称的元素的文本节点，而其他元素不需要，则可以在XSLT中指定cdata-section-elements属性<xsl:output>属性。 1}}声明。

以下是如何完成此操作的简短示例：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"
 cdata-section-elements="a b c d e"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>
</xsl:stylesheet>

对以下XML文档应用此转换时：

<Record>
    <a>10:30</a>
    <b>20:30</b>
    <c>10:60</c>
    <d>1:15</d>
    <e>1:03</e>
</Record>

产生了想要的正确结果：

<Record>
   <a><![CDATA[10:30]]></a>
   <b><![CDATA[20:30]]></b>
   <c><![CDATA[10:60]]></c>
   <d><![CDATA[1:15]]></d>
   <e><![CDATA[1:03]]></e>
</Record>

如果事先不知道元素名称集，可以使用生成另一个样式表的样式表，最终应该应用于XML文档以产生想要的结果：< / p>

<xsl:stylesheet version="1.0" xmlns:x="http://www.w3.org/1999/XSL/Transform"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xxx="xxx">
 <xsl:namespace-alias stylesheet-prefix="xxx" result-prefix="xsl"/>
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:key name="kElemByName" match="*[text()[normalize-space()]]" use="name()"/>

 <xsl:variable name="vDistinctNamedElems" select=
 "//*[generate-id()=generate-id(key('kElemByName',name())[1])]"/>

 <xsl:variable name="vDistinctNames">
  <xsl:for-each select="$vDistinctNamedElems">
   <xsl:value-of select="concat(name(), ' ')"/>
  </xsl:for-each>
 </xsl:variable>

 <xsl:template match="node()|@*">
  <xxx:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xxx:output omit-xml-declaration="yes" indent="yes"
       cdata-section-elements="{$vDistinctNames}"/>
    <xxx:strip-space elements="*"/>

    <xxx:template match="node()|@*">
     <xxx:copy>
       <xxx:apply-templates select="node()|@*"/>
     </xxx:copy>
    </xxx:template>
  </xxx:stylesheet>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于同一XML文档（上图）时，结果是另一个XSLT样式表：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:x="http://www.w3.org/1999/XSL/Transform"
                version="1.0">
   <xsl:output omit-xml-declaration="yes" indent="yes" cdata-section-elements="a b c d e "/>
   <xsl:strip-space elements="*"/>
   <xsl:template match="node()|@*">
      <xsl:copy>
         <xsl:apply-templates select="node()|@*"/>
      </xsl:copy>
   </xsl:template>
</xsl:stylesheet>

在此样式表中，cdata-section-elements属性中的所有元素名称都是动态生成的（使用Muenchian方法进行分组）。

当我们最终在同一个XML文档上应用如此生成的XSLT样式表时，我们得到想要的结果：

<Record>
   <a><![CDATA[10:30]]></a>
   <b><![CDATA[20:30]]></b>
   <c><![CDATA[10:60]]></c>
   <d><![CDATA[1:15]]></d>
   <e><![CDATA[1:03]]></e>
</Record>

<强>解释：

使用XSLT指令动态生成新转换 xsl:namespace-alias 。
Muenchian grouping 确定所有不同的元素名称。

Answer 2

您的解决方案是在cdatasection属性（cdata-section-elements）中引入包含uh的节点/元素的名称：

<xsl:output omit-xml-declaration="yes"
            indent="yes"
            cdata-section-elements="Name CompanyName Text"
/>

XML和XSLT保留CDATA

2 个答案: