Question

我有一个带有分组的flexgrid，以及一个分组的.subtotal。除了一个之外的所有列都是数字的，不是的那个列的格式为'x / y'，例如'1/5'，即提供的5个项目中的1个。

如果我使用flexSTSum执行.subtotal，它会对该对中的第一个数字求和，即在上面的示例中，它将1作为小数加总并在小计行中显示1.00

起初我试图找到一种方法来对另一列进行求和，即我可以将单个值放入单独的列中，给它们一个.Width为0并将它们加到第一列的.Subtotal列中，但我可以找不到办法。

即使我确实找到了一种方法，我希望能够自定义格式化.Subtotal，因此它显示为'3/17'，即'1/5'和'2/12'小计小计行中的“3/17”。

如果我不能对另一列进行小计，我想知道我是否可以自定义访问小计行并手动输入小计值'3/17'，但即使这样也无法使用。

我的问题是，有没有办法实现这个目标？

Answer 1

我假设您使用的是我从未使用过的VideoSoft FlexGrid，因此我无法帮助您了解该控件的具体方法。

您可以使用标准的MSFlexGrid控件轻松完成，并且您可以对VideoSoft FlexGrid执行相同的操作。

查看以下示例项目：

'1 form with :
'    1 msflexgrid control : name=MSFlexGrid1
Option Explicit

Private Sub Form_Load()
  Dim lngRow As Long, lngCol As Long
  With MSFlexGrid1
    .Rows = 10
    .Cols = 4
    .FixedRows = 0
    .FixedCols = 0
    For lngRow = 0 To .Rows - 2
      For lngCol = 0 To .Cols - 2
        .TextMatrix(lngRow, lngCol) = CStr(100 * lngRow + lngCol)
      Next lngCol
      .TextMatrix(lngRow, .Cols - 1) = CStr(lngRow) & "/" & CStr(lngRow * lngRow)
    Next lngRow
  End With 'MSFlexGrid1
End Sub

Private Sub Form_Resize()
  MSFlexGrid1.Move 0, 0, ScaleWidth, ScaleHeight
End Sub

Private Sub MSFlexGrid1_Click()
  Dim lngCol As Long
  'calculate subtotals
  With MSFlexGrid1
    For lngCol = 0 To .Cols - 2
      .TextMatrix(.Rows - 1, lngCol) = CStr(GetTotal(lngCol))
    Next lngCol
    .TextMatrix(.Rows - 1, .Cols - 1) = GetTotalSpecial(.Cols - 1)
  End With 'MSFlexGrid1
End Sub

Private Function GetTotal(lngCol As Long) As Long
  Dim lngRow As Long
  Dim lngTotal As Long
  With MSFlexGrid1
    lngTotal = 0
    For lngRow = 0 To .Rows - 2
      lngTotal = lngTotal + Val(.TextMatrix(lngRow, lngCol))
    Next lngRow
  End With 'MSFlexGrid1
  GetTotal = lngTotal
End Function

Private Function GetTotalSpecial(lngCol As Long) As String
  Dim lngRow As Long
  Dim lngTotal1 As Long, lngTotal2 As Long
  Dim strPart() As String
  With MSFlexGrid1
    lngTotal1 = 0
    lngTotal2 = 0
    For lngRow = 0 To .Rows - 2
      strPart = Split(.TextMatrix(lngRow, .Cols - 1), "/")
      If UBound(strPart) = 1 Then
        lngTotal1 = lngTotal1 + Val(strPart(0))
        lngTotal2 = lngTotal2 + Val(strPart(1))
      End If
    Next lngRow
  End With 'MSFlexGrid1
  GetTotalSpecial = CStr(lngTotal1) & "/" & CStr(lngTotal2)
End Function

它将加载一个带有一些值的网格，当你点击网格时，小计将被计算并填充到最后一行。

在vb6 flexgrid中手动输入小计值

1 个答案: