Question

有一个与此非常类似的问题，但我想对多个数组执行此操作。我有一个数组数组。

my @AoA = (
    $arr1 = [ 1, 0, 0, 0, 1 ],
    $arr2 = [ 1, 1, 0, 1, 1 ],
    $arr3 = [ 2, 0, 2, 1, 0 ]
);

我想总结所有三个（或更多）数组中的项目，以获得一个新的数组，如

( 4, 1, 2, 2, 2 )

use List::MoreUtils qw/pairwise/需要两个数组参数。

@new_array = pairwise { $a + $b } @$arr1, @$arr2;

我想到的一个解决方案是循环遍历@AoA并将前两个数组传递到pairwise函数中。在随后的迭代中，我会将@$arr中的下一个@AoA和@new_array传递给成对函数。在奇数大小的数组数组的情况下，在我传入@$arr中的最后@AoA后，我将传入一个大小相等的数组，其元素为0。

这是一个好方法吗？如果是这样，我该如何实现呢？感谢

Answer 1

您可以轻松实现“n-wise”功能：

sub nwise (&@) # ← take a code block, and any number of further arguments
{
  my ($code, @arefs) = @_;
  return map {$code->( do{ my $i = $_; map $arefs[$_][$i], 0 .. $#arefs } )}
             0 .. $#{$arefs[0]};
}

该代码有点难看，因为Perl不支持多维数组切片。相反，我使用嵌套的map s。

快速测试：

use Test::More;
my @a = (1, 0, 0, 0, 1);
my @b = (1, 1, 0, 1, 1);
my @c = (2, 0, 2, 1, 0);
is_deeply [ nwise { $_[0] + $_[1] + $_[2] } \@a, \@b, \@c], [4, 1, 2, 2, 2];

我更喜欢将数组作为引用传递，而不是使用\@或+原型：这可以让你做

my @arrays = (\@a, \@b, \@c);
nwise {...} @arrays;

从List::MoreUtils您也可以使用each_arrayref：

use List::Util qw/sum/;
use List::MoreUtils qw/each_arrayref/;
my $iter = each_arrayref @arrays;
my @out;
while (my @vals = $iter->()) {
  push @out, sum @vals;
}
is_deeply \@out, [4, 1, 2, 2, 2];

或者只是普通的旧循环：

my @out;
for my $i (0 .. $#a) {
  my $accumulator = 0;
  for my $array (@arrays) {
    $accumulator += $array->[$i];
  }
  push @out, $accumulator;
}
is_deeply \@out, [4, 1, 2, 2, 2];

以上都认为所有阵列都具有相同的长度。

关于您的代码段的说明：

你的数组结构的例子当然是合法的perl，它甚至可以按预期运行，但最好省略内部任务：

my @AoA = (
    [ 1, 0, 0, 0, 1 ],
    [ 1, 1, 0, 1, 1 ],
    [ 2, 0, 2, 1, 0 ],
);

Answer 2

您可能实际上正在寻找Perl数据语言PDL。它是Perl的数字数组模块。它有许多用于处理数据数组的函数。与其他语言的其他数值阵列模块不同，它具有在任意维度上使用其功能的便利能力，它将完成您的意思。请注意，这一切都是在C级完成的，因此效率很高！

在您的情况下，您正在寻找投影方法sumover，它将采用N维对象并返回通过对第一维进行求和而创建的N-1维对象。因为在你的系统中你要总结第二个，我们首先必须通过交换尺寸0和1进行转置。

#!/usr/bin/env perl

use strict;
use warnings;

use PDL;

my @AoA = (
    [ 1, 0, 0, 0, 1 ],
    [ 1, 1, 0, 1, 1 ],
    [ 2, 0, 2, 1, 0 ],
);

my $pdl = pdl \@AoA;

my $sum = $pdl->xchg(0,1)->sumover;
print $sum . "\n"; 
# [4 1 2 2 2]

从sumover返回的是另一个PDL对象，如果您需要Perl列表，可以使用list

print "$_\n" for $sum->list;

Answer 3

这是一个简单的迭代方法。它可能会对大型数据集执行得非常糟糕。如果您想要一个性能更好的解决方案，您可能需要更改数据结构，或者查看其中一个统计软件包的CPAN。以下假设所有数组的大小与第一个数组相同。

$sum = 0;
@rv = ();
for ($y=0; $y < scalar @{$AoA[0]}; $y++) {
    for ($x=0; $x < scalar @AoA; $x++) {
        $sum += ${$AoA[$x]}[$y];
    }
    push @rv, $sum;
    $sum = 0;
}

print '('.join(',',@rv).")\n";

Answer 4

假设：

AoA中的每一行将与第一行具有相同的列数。
arrayrefs中的每个值都是一个数字（具体地说，是一个与“=运算符”一起工作的格式的值）
至少有一个“行”至少有一个“列”

注意：“$＃{$ AoA [0]}”表示“@AoA中第一个arrayref的数组的最后一个元素（$＃）的索引（{$ AoA [0]}）”

(shebang)/usr/bin/perl
use strict;
use warnings;

my @AoA = (
    [ 1, 0, 0, 0, 1 ],
    [ 1, 1, 0, 1, 1 ],
    [ 2, 0, 2, 1, 0 ]
);

my @sums;

foreach my $column (0..$#{$AoA[0]}) {
  my $sum;
  foreach my $aref (@AoA){
    $sum += $aref->[$column];
  }
  push @sums,$sum;
}

use Data::Dumper;
print Dumper \@sums;

如何在Perl中以元素方式对多个数组求和？

4 个答案: