Question

我有一个旧的VB6应用程序，可以打开Word文档（.doc）。它在Windows XP上运行了很长时间。我的问题是，当我在Windows 7或Windows 8上安装应用程序时，代码将打开Word，但不会显示实际文档。当它打开Word时，我能够导航到文件并完全打开它，所以文件没有问题。好像我在这里遗漏了一些简单的东西，但经过大量的搜索和阅读后，我无法确定它。

我确保Word是与Windows 7和8计算机上的.doc文件关联的程序，所以不是这样。

以下是我用来打开文档的代码：

Dim iret As Long
iret = ShellExecute(hwnd, vbNullString, QuoteFilePath & File1.FileName,  vbNullString, "c:\", SW_SHOWNORMAL)

感谢任何帮助！

Answer 1

这个特殊文件夹实际上不应该用于存储用户文档的原因有很多。微软甚至第三方已经开始将它用于完全不同的目的。根据已安装的应用程序，您甚至可以在此处找到DLL。

如果您误导用户使用此文件夹，他们可能会删除对某些其他程序操作至关重要的文件。

但是如果你坚持这样做，那么用文字字符串值引用该文件夹是不安全的，因为它可以根据用户的语言设置在不同的别名下出现。它甚至可能通过行政行动重新安置在其他地方。

也没有必要弯腰使用非COM ShellExecute入口点，至少早在Shell32.dll的5.0版本就可以了。

至少应该从WinXP前进：

Option Explicit

Private Const ssfCOMMONDOCUMENTS As Long = &H2E
Private Enum SHOW_WINDOW
    SW_HIDE = 0
    SW_SHOWNORMAL = 1
    SW_SHOWMINIMIZED = 2
    SW_SHOWMAXIMIZED = 3
    SW_SHOWNOACTIVATE = 4
    SW_SHOW = 5
    SW_SHOWMINNOACTIVE = 7
    SW_SHOWDEFAULT = 10
End Enum

Private Shell As Object
Private Path As String

Private Sub File1_Click()
    On Error Resume Next
    'Works on XP through Vista, fails on Win7:
    'Shell.ShellExecute File1.FileName, , Path, "open", SW_SHOWNORMAL

    'Works on XP through Win7:
    Shell.ShellExecute Path & "\" & File1.FileName, , , "open", SW_SHOWNORMAL
    If Err Then
        MsgBox "Error " & CStr(Err.Number) & " " & Err.Description
    End If
End Sub

Private Sub Form_Load()
    Set Shell = CreateObject("Shell.Application")
    With Shell.NameSpace(ssfCOMMONDOCUMENTS).Self
        Path = .Path
    End With
    With File1
        .Pattern = "*.doc"
        .Path = Path
    End With
End Sub

在Windows 7/8问题中从VB6打开Word文档

1 个答案: