Question

我知道 xs !! n 给了我列表中的第n个元素，但我不知道如何编辑该列表中的第n个元素。你能告诉我如何编辑列表中的第n个元素或至少给出一个提示？例如，如何将第二个元素'a'设为'e'：['s'，'t'，'a'，'c'，'k']？感谢。

Answer 1

更改第n个元素

许多语言的常见操作是分配给数组中的索引位置。在python中你可以：

>>> a = [1,2,3,4,5]
>>> a[3] = 9
>>> a
[1, 2, 3, 9, 5]

在 lens包为(.~)运算符提供此功能。虽然与python不同，原始列表不会发生变异，而是返回一个新列表。

> let a = [1,2,3,4,5]
> a & element 3 .~ 9
[1,2,3,9,5]
> a
[1,2,3,4,5]

element 3 .~ 9只是一个函数而(&)运算符是其中的一部分 lens包，只是反向功能应用程序。这里有更常见的功能应用。

> (element 3 .~ 9) [1,2,3,4,5]
[1,2,3,9,5]

使用Traversable s的任意嵌套再次分配工作完全正常。

> [[1,2,3],[4,5,6]] & element 0 . element 1 .~ 9
[[1,9,3],[4,5,6]]

或

> set (element 3) 9 [1,2,3,4,5,6,7]

或者，如果您想要影响多个元素，可以使用：

> over (elements (>3)) (const 99) [1,2,3,4,5,6,7]
> [1,2,3,4,99,99,99]

使用其他类型列表

这不仅限于列表，但它适用于作为Traversable类型类实例的任何数据类型。

例如，相同的技术适用于标准trees containers包。

 > import Data.Tree
 > :{
 let
  tree = Node 1 [
       Node 2 [Node 4[], Node 5 []]
     , Node 3 [Node 6 [], Node 7 []]
     ]
 :}
> putStrLn . drawTree . fmap show $ tree
1
|
+- 2
|  |
|  +- 4
|  |
|  `- 5
|
`- 3
   |
   +- 6
   |
   `- 7
> putStrLn . drawTree . fmap show $ tree & element 1 .~ 99
1
|
+- 99
|  |
|  +- 4
|  |
|  `- 5
|
`- 3
   |
   +- 6
   |
   `- 7
> putStrLn . drawTree . fmap show $ tree & element 3 .~ 99
1
|
+- 2
|  |
|  +- 4
|  |
|  `- 99
|
`- 3
   |
   +- 6
   |
   `- 7
> putStrLn . drawTree . fmap show $ over (elements (>3)) (const 99) tree
1
|
+- 2
|  |
|  +- 4
|  |
|  `- 5
|
`- 99
   |
   +- 99
   |
   `- 99

Answer 2

因为Haskell是一种函数式语言，所以你不能“编辑”列表中的元素，因为一切都是不可变的。相反，您可以使用以下内容创建新列表：

take n xs ++ [newElement] ++ drop (n + 1) xs

但是，不建议在Haskell中使用。有关更多信息，请参阅此帖子：Haskell replace element in list

Answer 3

您无法编辑列表的第n个元素，值是不可变的。您必须创建一个新列表。但由于不变性，它可以在更改后的元素与原始列表之后共享该部分。

因此，如果要将变换应用于列表的第n个元素（并且在相同之前和之后具有部分），则有三个部分

相关元素前面的列表前面，说front
有问题的元素，比如element
在相关元素后面的列表背面，说back。

然后你要组装零件

front ++ transform element : back

所以仍然可以很好地掌握有趣的部分。

splitAt :: Int -> [a] -> ([a],[a])

这样做，splitAt idx list返回列表的第一部分，在索引idx作为对的第一部分之前，其余部分作为第二部分，所以

changeNthElement :: Int -> (a -> a) -> [a] -> [a]
changeNthElement idx transform list
    | idx < 0   = list
    | otherwise = case spliAt idx list of
                    (front, element:back) -> front ++ transform element : back
                    _ -> list    -- if the list doesn't have an element at index idx

（注意：我已经开始将元素计数为0，如果你想从1开始计数，你需要调整并使用idx-1。）

Answer 4

我很惊讶尚未提及以下方法，因此我将其添加以作进一步参考：

replace index elem = map (\(index', elem') -> if index' == index then elem else elem') . zip [0..]

> replace 2 'e' "stack"
"steck"

它可以处理超出范围的索引。

> replace (-1) 'z' "abc"
"abc"
> replace 0 'z' "abc"
"zbc"
> replace 2 'z' "abc"
"abz"
> replace 3 'z' "abc"
"abc"

它不比splitAt方法（O（2N））慢。

如何在Haskell列表中编辑第n个元素？

4 个答案:

更改第n个元素

使用其他类型列表