如何使用Gnuplot将符号放在绘图的特定点上

Question

Here提供了使用Gnuplot绘制的绘图中的换行示例。

使用箭头，如上面的链接所示，结果取决于轴，即我无法简单地处理箭头的角度。下图显示了上面链接中的示例获得的丑陋换行的示例。

为了获得那些丑陋的箭头，我做了类似的事情：

x1 = 32
yb = 0
yt = 100
tiny=2
set arrow 1 from x1-tiny, yb-tiny to x1+tiny, yb+tiny nohead
set arrow 2 from x1-tiny, yt-tiny to x1+tiny, yt+tiny nohead

第一个情节和：

x2 = 33
set arrow 1 from x2-tiny, yb-tiny to x2+tiny, yb+tiny nohead
set arrow 2 from x2-tiny, yt-tiny to x2+tiny, yt+tiny nohead

第二个。

因此，我希望使用符号放在轴的末端，而不是使用箭头。符号在pt中，并且不随轴长度而变化。我认为应该通过将标签置于特定点的中心来完成。

在Gnuplot中执行此操作的代码是什么？

Answer 1

分别为第一个和后一个图尝试以下行：

set label "/" at x1, yb center font "Symbol,24"
set label "/" at x1, yt center font "Symbol,24"

set label "/" at x2, yb center font "Symbol,24"
set label "/" at x2, yt center font "Symbol,24"

这应该有效！

Answer 2

以固定角度指定箭头的技巧是在图形坐标中工作。

（注意我的split axis方法不适用于postscipt驱动程序......不知道为什么）

set terminal png
set yrange [0:20]
set multiplot
set ytics nomirror
set xrange [0:10]
set border 7  #left,top,bottom
set key left
dy = .025  #height of slash in graph coordinates
dx = dy/tan(10*pi/180)  # 10 degree angle
set arrow nohead lt -1 from graph 1-dx,-dy to graph 1+dx,dy
set origin 0,0
set size .5,.8 
set xtics (0,4,8)
plot sqrt(x)
set origin .5,0
set xrange [100:200]
set border 13 #right,top,bottom
unset ytics
set nokey
unset arrow
set arrow nohead lt -1 from graph -dx,-dy to graph dx,dy 
set xtics (125,150,175,200)
plot sqrt(x)

请注意，如果您有日志比例，这将正常工作..

哎哟忘记了顶部，因为你只是做了

set arrow nohead lt -1 from graph 1-dx,-dy+1 to graph 1+dx,dy+1