Question

我有一个值y，我想知道这个值是否在这组值中：x1, x2, ... xn。

我可以这样做：

if(y = x1 or y = x2 or .....)

但是有更好的方法吗？伪代码：

if(y in (x1, x2, ...., xn))

Answer 1

你可以写一个像这样的辅助函数：

Public Function FindValue(ByVal ValueToFind As Variant, ParamArray SearchIn() As Variant)

    Dim i As Integer

    For i = 0 To UBound(SearchIn)
        If SearchIn(i) = ValueToFind Then
            FindValue = True
            Exit Function
        End If
    Next

End Function

第二个参数（ParamArray）是一个数组，因此您实际上可以传递无限数量的参数。

所以你可以把你所有的值传递给这个函数 - 你想要先找到的那个，然后是你要搜索的所有值：

Dim Found As Boolean

Found = FindValue(y, x1, x2, x3, xn)

Answer 2

您可以使用Select Case的相同方式（如果是其他）：

Select Case Y
       Case X1, X2, X3, ...
            Do if True
       Case Else
            Do if False
End Select

Answer 3

使用数组：

dim x(10)

x(1)=....
x(2)=....

y=....

for i=1 to 10
    if x(i)=y then
         ....
    end if
next i

Answer 4

dim values as string
values = "1,2,3,4,5,"  'Note that comma is a separator and added towards the end as well.

dim lookupValue as string
lookupValue = ",4,"

dim found as Boolean
found = (instr(1, values, lookupValue) <> 0)

if found then


end if

编辑：另一种方式

dim lookupValue as long
lookupValue = 21000

dim values
set values = CreateObject("Scripting.Dictionary")

with values
   .Add 1, 1
   .Add 10, 1
   .Add 100, 1
   .Add 1000, 1
   .Add 10000, 1
end with

dim found as Boolean
found = values.Exists(lookupValue)

Answer 5

很容易想到检查值是否存在是使用Match函数：

Dim myTBL As Variant
    myTBL = Array(20, 30, 40, 50, 60)

'if value '30' exists in array than the position (which is >0) will be returned
    Debug.Print WorksheetFunction.Match(30, myTBL, 0)

唯一的问题是，如果该值不存在，Match函数将返回错误。因此，您应该使用错误处理技术。

对于非现有值'70'，这可能看起来像是：

'if doesn't exists error would be returned
On Error Resume Next
    Debug.Print WorksheetFunction.Match(70, myTBL, 0)
If Err.Number <> 0 Then
    Debug.Print "not exists"
    Err.Clear
End If

不幸的是，这只适用于Excel。

Answer 6

另一种方式

您是否可以访问MS-Access 2000+？如果是这样，添加Access Objects库引用，您将能够使用Eval函数：

result = Eval("'y' IN ('x1', 'x2', '...' 'xn')")

它评估字符串表达式。可以使用某些SQL运算符，如IN。见documentation

Answer 7

选择一个在任何值中都不存在的定界符（例如，管道“ |”），就可以一行完成：

If "|x1|x2|...|xn|" Like "*|" & y & "|*" Then

VBA发现值是否在值中

7 个答案: