Question

这些键映射在tmux中停止工作。在我的.vimrc中，我有：

nmap <Space> i
map <C-Down> <C-w>j
map <C-Up> <C-w>k
map <C-Left> <C-w>h
map <C-Right> <C-w>l

当我运行:map时，我看到了：

   <C-Right>     <C-W>l
   <C-Left>      <C-W>h
   <C-Up>        <C-W>k
   <C-Down>      <C-W>j

然而，当我同时按下控制键和箭头键时，它表现得好像没有设置键绑定。

Answer 1

Vim知道 xterm 类终端（由xterm开始的TERM标识，或t_RV序列的特定响应（如果已定义）支持扩展序列对于某些已修改的密钥，但它不会对screen TERM（您应该在 tmux 下使用）假设这一点。

然而，如果存在TMUX，您可以告诉Vim这些序列并启用它们，并且TERM以screen开头（第一行在 tmux 下启用（更好）鼠标支持，你可能也喜欢）：

if &term =~ '^screen' && exists('$TMUX')
    set mouse+=a
    " tmux knows the extended mouse mode
    set ttymouse=xterm2
    " tmux will send xterm-style keys when xterm-keys is on
    execute "set <xUp>=\e[1;*A"
    execute "set <xDown>=\e[1;*B"
    execute "set <xRight>=\e[1;*C"
    execute "set <xLeft>=\e[1;*D"
    execute "set <xHome>=\e[1;*H"
    execute "set <xEnd>=\e[1;*F"
    execute "set <Insert>=\e[2;*~"
    execute "set <Delete>=\e[3;*~"
    execute "set <PageUp>=\e[5;*~"
    execute "set <PageDown>=\e[6;*~"
    execute "set <xF1>=\e[1;*P"
    execute "set <xF2>=\e[1;*Q"
    execute "set <xF3>=\e[1;*R"
    execute "set <xF4>=\e[1;*S"
    execute "set <F5>=\e[15;*~"
    execute "set <F6>=\e[17;*~"
    execute "set <F7>=\e[18;*~"
    execute "set <F8>=\e[19;*~"
    execute "set <F9>=\e[20;*~"
    execute "set <F10>=\e[21;*~"
    execute "set <F11>=\e[23;*~"
    execute "set <F12>=\e[24;*~"
endif

如评论所示，您还需要启用窗口的xterm-keys选项。您可以对所有窗口执行此操作（在~/.tmux.conf中）：

set-option -gw xterm-keys on

（请记住，~/.tmux.conf的更改不会自动加载。为了有效，您需要手动运行此命令（在tmux shell命令中或在前缀:提示），或者使用source ~/.tmux.conf（在tmux shell命令中或在前缀:提示符下）重新加载配置文件，或者重新启动服务器（退出所有会话并重新启动） TMUX ））。

运行tmux时映射箭头键

1 个答案: