Question

以下是我在perl中发送html电子邮件的代码

use strict;
use warnings;

use Email::Sender::Simple qw(sendmail);
use Email::Sender::Transport::SMTP ();
use Email::Simple ();
use Email::Simple::Creator ();
use Email::MIME::CreateHTML;


my $smtpserver = 'xxx.xxx.xx';
my $smtpport = 25;
my $smtpuser   = 'xxx@test.com';
my $smtppassword = 'xxxx';

my $transport = Email::Sender::Transport::SMTP->new({
  host => $smtpserver,
  port => $smtpport,
  sasl_username => $smtpuser,
  sasl_password => $smtppassword,
});


my $html ="<div>Success</div>";
my $plain_text ="plain text";

my $email = Email::MIME->create_html(
        header => [
                From => 'test@lintotest.com',
                To => 'linodavis@gmailcom',
                Subject => 'Test Mail',
        ],
        body => $html,
        text_body => $plain_text
);

sendmail($email, { transport => $transport });

它的工作正常。现在我需要找到邮件发送的响应。

因为我将代码修改为

eval {
sendmail($email, { transport => $transport });    # this is try catch method
};
if ($@) {
        # where $@ is a object of Email::Sender::Failure
    print $@->message;
    print"\n".$@->code ;

}else{
 print "success";
}

现在让我知道，有没有更好的方法来实现这个目标？

Answer 1

可以改善代码的两件事。

首先，尽快采用$@的副本（如果您在处理错误时执行的操作会更改$@的值），这始终是一种好习惯。

if (my $e = $@) {
    print $e->message;
    print"\n" . $e->code;
}

其次，同样值得考虑像Try::Tiny之类的模块，它会使你的异常处理代码看起来更好。

try {
    sendmail($email, { transport => $transport });
} catch {
    # Exception is in $_
    print $_->message;
    print"\n" . $_->code;
}

如何在perl中发送html邮件时获得响应（成功或失败）

1 个答案: