Question

这是一个简单的Perl脚本，它接受2个参数 - 一个字符串（一个URL）和一个整数值。

我所要做的就是在给定的时间段（以秒为单位）内对传递的URL运行curl请求。

当网址像http://admin:admin@localhost:5074/?q=james一样简单时，一切都很顺利，但问题出现在网址中有&。

问题是system()使得curl请求在退出循环后仍然保持运行。

发生了什么事？

use strict;
use warnings;
use URI::Escape;

my $url = uri_escape($ARGV[0]);
print "URL=".$url."\n"; 
my $duration = $ARGV[1];
print $duration;
my $start = time(); 
my $end = $start + $duration;
my $request = 0;

while(time() <= $end ){ 
    system("curl --user admin:admin --digest ".uri_unescape($url)); 
    $request++;
}

print "------------------------ END ----------------------------------\n";
print "URL = ".uri_unescape($url)." \n";
print "Total requests made = ".$request."\n";
print "Reqs/sec = ".($request/$duration)."/sec \n";
#print $start."\n";
#print $end."\n";
print "Duration = ".$duration." sec \n";
print "-------------------------------------------------------------------\n";

命令是：

perl curl.pl "http://admin:admin@localhost:5074/?q=james&format=xml" 5

Answer 1

您的网址中有一个&字符，由shell解释为“在后台运行此命令”。您需要正确地转义&等元字符，以避免shell解释它们，或者通过：

use String::ShellQuote qw( shell_quote );
system("curl --user admin:admin --digest " . shell_quote($url));

或首选：

system('curl', '--user', 'admin:admin', '--digest', $url);

后者完全避免创建shell，并且直接使用给定参数分叉/执行curl，这些参数会自动转义。它更快，更安全。有关详细信息，请参阅system perldoc。

另外，您应该考虑使用LWP。它是新Perls的Perl核心的一部分（无需安装），您无需担心逃避任何事情。

Perl system（）命令甚至在退出循环后运行

1 个答案: