Question

我有以下文件：

a b 5
c d 6
e f 7
g h 4
i j 3
k l 10

我希望找到哪一行显示第三列中的最小值并将其从初始文件中删除。在此之后，我想再次迭代程序并再次找到最小的行，并再次做同样的事情。

输出文件应为

c d 6
e f 7
k l 10

我尝试编写以下代码：

#!/usr/bin/perl

use strict;
use warnings;
use feature 'say';

my $file1 = "try.dat";
open my $fg,  "<", $file1 or die "Error during $file1 opening: $!";

my @vector;

while (<$fg>) {
    push @vector, [ split ];
}

my $minimum = $vector[0][2];
my @blacklist;
for my $i (0 .. $#vector) {
    if ($minimum > $vector[$i][2]){
    $minimum = $vector[$i][2];
    push @blacklist, @vector[$i+1]; 
    }
}
#say "my minimum is $minimum";
#say "the blacklist is composed by @blacklist";

我不知道如何删除@blacklist所包含的元素（在第一种情况下应该是i j 3）以及如何迭代所有内容。

迭代的任何帮助？

Answer 1

这是Tie::File所做的事情。它允许您通过修改绑定数组来就地修改文件。

这个程序可以满足您的需求。辅助函数minidx返回包含最小值的传递数组元素的第一个索引。

该程序的工作原理是将文件记录的第三个字段复制到数组@field3中，并在那里找到最小值的索引。然后，使用@field3从文件和splice删除该索引处的元素。

use strict;
use warnings;

use Tie::File;

tie my @file, 'Tie::File', 'file.txt' or die $!;

my @field3 = map { (split)[2] } @file;
for (1 .. 3) {
  my $i = minidx(\@field3);
  splice @file, $i, 1;
  splice @field3, $i, 1;
}

sub minidx {
  my ($arr) = @_;
  my ($i, $v);
  for (0 .. $#$arr) {
    ($i, $v) = ($_, $arr->[$_]) unless defined $v and $arr->[$_] >= $v;
  }
  return $i;
}

<强>输出

c d 6
e f 7
k l 10

Answer 2

当您说@blacklist = @vector时，您要将整个@vector数组添加到黑名单中。您可能想要push @blacklist, $vector[$i]。这将把阵列引用推入黑名单。

现在，黑名单中有一个数组引用，所以你必须遵循它来打印它。

say "the blacklist is composed by @{$blacklist[0]}";

编辑：用于迭代和写作：

我会跳过@blacklist数组（除非您需要其他内容）并从@vector中删除最小值。然后，您可以将@vector写入某个文件。

my $num_elts_to_remove = 3;
for (my $j = 0; $j < $num_elts_to_remove; $j++) {
  my $minimum = $vector[0][2];
  my $min_idx = 0;
  for my $i (0 .. $#vector) {
      if ($minimum > $vector[$i][2]){
        $minimum = $vector[$i][2];
        $min_idx = $i;
      }
  }
  push @blacklist, $vector[$min_index];
  splice @vector, $min_idx, 1; #remove array with smallest value
}

现在将数组写入文件

open OUT, ">", $outfile or die "Error: $!";
foreach(@vector) {
    print OUT join " ", @$_;
    print OUT "\n";
}
close(OUT);

打印：

c d 6
e f 7
k l 10

Answer 3

进一步考虑Borodin的Tie :: File建议。我编写了一个名为Tie::Array::CSV的可爱模块，它允许您将分隔文件视为数组（因为它使用下面的Tie :: File，它既可以读写也可以写入）。因此，我可以使用Perlish操作，如map和sort（以及Schwartzian transform！）来执行此任务：

#!/usr/bin/env perl

use strict;
use warnings;

use Tie::Array::CSV;

tie my @data, 'Tie::Array::CSV', 'data', sep_char => ' ';

# get a list of row ids sorted by last value (inc)
my $i = 0;
my @sorted = 
  map  { $_->[0] } 
  sort { $a->[1] <=> $b->[1] }
  map  { [$i++, $_->[-1]] } 
  @data;

#splice the rows by index of the lowest three (from bottom to top)
splice @data, $_, 1 for reverse sort @sorted[0..2];

请注意，最后您要从底部删除行，这样您就不必每次都重新编制索引。

迭代一个简单的程序

3 个答案: