Question

我有一个xml文件，其中标签的属性是其他xml文件的src。

 <a>
    <b>
       <c src="other1.xml" name="other1"></c>
       <c src="other2.xml" name="other2"></c>
       <c src="other3.xml" name="other3"></c> 
   </b>
 </a>

我想将此xml文件的内容更改为以下格式

<a>
    <b>
       <other1> content of other1.xml </other1>
       <other2> content of other2.xml </other2>
       <other3> content of other3.xml </other3>
   </b>
</a>

我尝试使用xsl：variable并在其中存储src的值但是我收到了错误。

有人请建议解决方案....即使提示也将受到赞赏

Answer 1

这应该这样做：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes"/>

  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="c">
    <xsl:element name="{@name}">
      <xsl:apply-templates select="document(@src)" />
    </xsl:element>
  </xsl:template>
</xsl:stylesheet>

使用以下文件：other1.xml，other2.xml和other3.xml：

<I xmlns="hello">
  <am some="" xml="" />
</I>

<I xmlns="hello">
  <amAlso xml="" />
</I>

<I>
  <am xml="as well" />
</I>

以示例XML作为输入运行，结果为：

<a>
  <b>
    <other1>
      <I xmlns="hello">
        <am some="" xml="" />
      </I>
    </other1>
    <other2>
      <I xmlns="hello">
        <amAlso xml="" />
      </I>
    </other2>
    <other3>
      <I>
        <am xml="as well" />
      </I>
    </other3>
  </b>
</a>

使用xslt将一个xml文件的内容复制到另一个xml文件中

1 个答案: