Question

如何计算Delphi中字符串中某个字符的出现次数？

例如，假设我有以下字符串并且想要计算其中逗号的数量：

S := '1,2,3';

然后我想获得2作为结果。

Answer 1

您可以使用这个简单的功能：

function OccurrencesOfChar(const S: string; const C: char): integer;
var
  i: Integer;
begin
  result := 0;
  for i := 1 to Length(S) do
    if S[i] = C then
      inc(result);
end;

Answer 2

即使已经接受了答案，我也会在下面发布更通用的功能，因为我发现它非常优雅。此解决方案用于计算字符串而不是字符的出现次数。

{ Returns a count of the number of occurences of SubText in Text }
function CountOccurences( const SubText: string;
                          const Text: string): Integer;
begin
  Result := Pos(SubText, Text); 
  if Result > 0 then
    Result := (Length(Text) - Length(StringReplace(Text, SubText, '', [rfReplaceAll]))) div  Length(subtext);
end;  { CountOccurences }

Answer 3

对于那些喜欢现代Delphi版本中的枚举器循环的人（不比Andreas公认的解决方案更好，只是一种替代解决方案）：

function OccurrencesOfChar(const ContentString: string;
  const CharToCount: char): integer;
var
  C: Char;
begin
  result := 0;
  for C in ContentString do
    if C = CharToCount then
      Inc(result);
end;

Answer 4

如果您不处理大文本

，这个可以完成工作

...

uses RegularExpressions;

...

function CountChar(const s: string; const c: char): integer;
begin
 Result:= TRegEx.Matches(s, c).Count
end;

Answer 5

您可以将StringReplace函数的好处用作：

function OccurencesOfChar(ContentString:string; CharToCount:char):integer;
begin
   Result:= Length(ContentString)-Length(StringReplace(ContentString, CharToCount,'', [rfReplaceAll, rfIgnoreCase]));
end;

Answer 6

简单的解决方案和良好的性能（我为Delphi 7撰写，但也适用于其他版本）：

function CountOccurences(const ASubString: string; const AString: string): Integer;
var
  iOffset: Integer;
  iSubStrLen: Integer;
begin
  Result := 0;

  if (ASubString = '') or (AString = '') then
    Exit;

  iOffset := 1;
  iSubStrLen := Length(ASubString);
  while (True) do
  begin
    iOffset := PosEx(ASubString, AString, iOffset);
    if (iOffset = 0) then
      Break;
    Inc(Result);
    Inc(iOffset, iSubStrLen);
  end;
end;

Answer 7

嗯……我错过了什么吗？为什么不只是...

      kSepChar:=',';//to count commas
      bLen:=length(sLineToCheck);
      bCount:=0;//The numer of kSepChars seen so far.
      bPosn:=1;//First character in string is at position 1
      for bPosn:=1 to bLen do begin
         if sLineToCheck[bPosn]=kSepChar then inc(bCount);
         end;//

如何计算字符串中某个char的出现次数？

7 个答案: