Question

我有以下cmd脚本没有产生我期望的结果：

set parent=src\Sandbox
set child=src\Sandbox\SandboxTest
echo %parent%
for /F "tokens=* delims=%parent%\" %%i in ("%child%") do set DIRNAME=%%i
echo %DIRNAME%

％DIRNAME％将作为“测试”返回，但我希望DIRNAME为“SandboxTest”。

任何人都有任何想法，为什么会这样？我的delims有问题吗？

谢谢，基思

Answer 1

您想使用变量引用语法。

set parent=src\Sandbox
set child=src\Sandbox\SandboxTest
echo %parent%
for /F %%i in ("%child%") do (
    set DIRNAME=%%~ni
    )

delims是用于拆分的字符数组

set parent=aeiou
set child=abcdefghijklmnopqrstuvwxyz
for /F "tokens=1-10 delims=%parent%\" %%a in ("%child%") do (
    echo.%%a
    echo.%%b
    echo.%%c
    echo.%%d
    echo.%%e
    )

它分裂人物而不是单词。

bcd
fgh
jklmn
pqrst
vwxyz

输入for /?以获取全部变量引用语法。

In addition, substitution of FOR variable references has been enhanced.
You can now use the following optional syntax:

    %~I         - expands %I removing any surrounding quotes (")
    %~fI        - expands %I to a fully qualified path name
    %~dI        - expands %I to a drive letter only
    %~pI        - expands %I to a path only
    %~nI        - expands %I to a file name only
    %~xI        - expands %I to a file extension only
    %~sI        - expanded path contains short names only
    %~aI        - expands %I to file attributes of file
    %~tI        - expands %I to date/time of file
    %~zI        - expands %I to size of file
    %~$PATH:I   - searches the directories listed in the PATH
                   environment variable and expands %I to the
                   fully qualified name of the first one found.
                   If the environment variable name is not
                   defined or the file is not found by the
                   search, then this modifier expands to the
                   empty string

The modifiers can be combined to get compound results:

    %~dpI       - expands %I to a drive letter and path only
    %~nxI       - expands %I to a file name and extension only
    %~fsI       - expands %I to a full path name with short names only
    %~dp$PATH:I - searches the directories listed in the PATH
                   environment variable for %I and expands to the
                   drive letter and path of the first one found.
    %~ftzaI     - expands %I to a DIR like output line

Answer 2

DELIMS没有定义分隔符短语 - 它定义了一组分隔符字符。 “测试”中的所有字符都不会出现在DELIMS集中，因此也就是结果。

在您引用的特例中，您可以使用以下方法获得所需的结果：

for %%F in ("%child%") do set DIRNAME=%%~nxF

Delim的CMD脚本问题

2 个答案: