Question

我正在寻找一个关于如何在尝试通过jQuery.Ajax将数据检索为JSon时如何使用SlickGrid的简单示例。我也无法找到SlickGrid插件的任何文档，并想知道我是否只是在寻找错误的地方。任何让我开始使用SlickGrid的帮助都会非常感激。

Answer 1

我一直在写一个ajax光滑网格。它一直很好，所以它绝对是一个值得追求的想法。

我使用了skip-take模型来批量下载大量数据。我还为光滑网格设置和操作编写了一个包装器Grid类，因此更容易重用。

以下是一些我希望可以帮助您入门的代码。我已将其删除以使其特定于您的AJAX加载问题。真正的网格使用了列过滤器和复选框选择器，这两者都值得调查，但会对回复进行模糊处理。

语法是CoffeeScript，但我相信你可以理解。

SlickGrid Wrapper

class Grid
    grid = null
    dataView = null
    options = {
        enableCellNavigation: true,
        explicitInitialization: true
    }

    constructor:(@gridId, @pagerId, @columns, loadData)->
        @setupDataView()
        @setupGrid()
        @setupPager()
        grid.init()
        loadData()

    setupDataView:() ->
        dataView = new Slick.Data.DataView()
        dataView.onRowCountChanged.subscribe(->
            grid.updateRowCount()
            grid.render()
        )
        dataView.onRowsChanged.subscribe((e, args)->
            grid.invalidateRows(args.rows)
            grid.render()
        )

    setupGrid:()->
        grid = new Slick.Grid(@gridId, dataView, @columns, options)
        grid.setSelectionModel(new Slick.RowSelectionModel())

    setupPager:() ->
        dataView.setPagingOptions({ pageSize: 25 });
        pager = new Slick.Controls.Pager(dataView, grid, $(@pagerId));

    addRows:(rows)->
        dataView.beginUpdate()
        dataView.addItem row for row in rows 
        dataView.endUpdate()

为用户网格实施包装

viewdata = $('#viewdata').data('viewdata')
take = 800
grid = null
loadingGlyph = '<img class="loading" style="float:right;margin-top:5px" src="/Content/img/ajax-loader.gif" alt="loading" width="16" height="16"/>'

columns = [
    { id: 'last name', name: 'Last Name', field: 'LastName', sortable:true },
    { id: 'first name', name: 'First Name', field: 'FirstName', sortable:true },
    { id: 'email', name: 'Email', field: 'Email', sortable:true }
]

loadData=() =>
    $('.slick-pager-status').after(loadingGlyph)
    for skip in [0..viewdata.count] by take
        url = '/' + viewdata.id + '/users/' + skip + '/' + take
        $.getJSON(url, (users) ->
            grid.addRows(users)
            $('.loading').hide() if users.length < take
        )

$ -> 
    grid = new Grid('#user-grid', '#user-pager', columns, loadData)

HTML

<div style="margin: 10px;">
    <div id="user-grid" style="width: 100%; height: 700px;"></div>
    <div id="user-pager" style="width: 100%; height: 20px;"></div>
</div>

有些SQL可以提供您的想法

select * from 
(
    select Id, FirstName, LastName, Email, ROW_NUMBER() over (order by UserName) rownum
    from [.. your stuff]
    where [... your stuff]
) seq
where seq.rownum between @skip and @count

Answer 2

对于任何想要这样做的人来说，请查看这个slickgrid的分支。 https://github.com/harbulot/SlickGrid

它添加了一个很好的小型本地Python服务器来提供AJAX后端

git clone git@github.com:harbulot/SlickGrid.git
cd SlickGrid/
python localajaxserver.py

然后使用浏览器转到http://127.0.0.1:8000/examples/example6b-ajax-localserver.html。

查看Pull Request以查看更改内容https://github.com/harbulot/SlickGrid/compare/mleibman:master...url_builder

使用ajax的光滑网格示例

2 个答案: