Question

我有一些带有ui元素的Flex s:Group，我希望它始终（！）位于我的应用程序内的任何组件之上，包括s:TitleWindow（对话框）。如何使用Flex 4实现它？

提前致谢！

Answer 1

您应该使用mx.managers.PopUpManager课程。它提供了一个简单的界面来处理显示任何其他内容的内容。

您可以编写自己的封装PopUpManager界面的界面，让您有机会再次将所有“永远在线”组件放在首位，即使您添加了另一个应该出现在后面的弹出窗口。

简单示例：

public final class AlwaysOnTopPopUpManager {

    private static var alwaysOnTopDisplayObjects:Array;

    public static function addAlwaysOnTopObject(displayObject:IFlexDisplayObject):void
    {
        alwaysOnTopDisplayObjects = alwaysOnTopDisplayObjects || [];

        if (alwaysOnTopDisplayObjects.indexOf(displayObject) == -1)
        {
            alwaysOnTopDisplayObjects.push(displayObject);
            arrange();
        }
    }


    public static function removeAlwaysOnTopObject(displayObject:IFlexDisplayObject):void
    {
        if (alwaysOnTopDisplayObjects)
        {
            var index:int = alwaysOnTopDisplayObjects.indexOf(displayObject);

            if (index != -1)
            {
                alwaysOnTopDisplayObjects.splice(index, 1);
            }
        }
    }


    // uses the same interface as mx.managers.PopUpManager
    public static function addPopUp(window:IFlexDisplayObject, parent:DisplayObject, modal:Boolean = false, childList:String = null, moduleFactory:IFlexModuleFactory = null):void
    {
        mx.managers.PopUpManager.addPopUp(window, parent, modal, childList, moduleFactory);
        arrange();
    }


    private static function arrange():void
    {
        for each (var popup:IFlexDisplayObject in alwaysOnTopDisplayObjects)
        {
            mx.managers.PopUpManager.bringToFront(popup);
        }
    }

该类包含要在任何其他内容上方显示的对象列表。每次将对象添加到该列表或弹出窗口时，都会调用arrange()方法并将所有已注册的对象重新置于前面。

Answer 2

在应用程序creationComplete事件之后，在systemManager.rawChildren中添加顶级组件。见下：

<?xml version="1.0" encoding="utf-8"?>
<s:Application xmlns:fx="http://ns.adobe.com/mxml/2009" 
               xmlns:s="library://ns.adobe.com/flex/spark" 
               creationComplete="application_creationCompleteHandler(event)"
               xmlns:mx="library://ns.adobe.com/flex/mx" minWidth="955" minHeight="600">
    <fx:Script>
        <![CDATA[
            import mx.core.UIComponent;
            import mx.events.CloseEvent;
            import mx.events.FlexEvent;
            import mx.managers.PopUpManager;

            protected function application_creationCompleteHandler(event:FlexEvent):void
            {
                panel.width = width;
                panel.height = 300;
                systemManager.rawChildren.addChild(panel);
            }

            protected function addPopup():void
            {
                PopUpManager.addPopUp(titleWin, this, true);
                PopUpManager.centerPopUp(titleWin);
            }

            protected function button_clickHandler(event:MouseEvent):void
            {
                addPopup();
            }

            protected function titleWin_closeHandler(evt:CloseEvent):void 
            {
                PopUpManager.removePopUp(evt.currentTarget as UIComponent);
            }
        ]]>
    </fx:Script>
    <fx:Declarations>
        <s:Panel id="panel" backgroundColor="0x00ff00" alpha="0.9" title="Panel">
            <s:layout>
                <s:VerticalLayout paddingLeft="50" horizontalAlign="left" verticalAlign="middle" />
            </s:layout>
            <s:Button id="btn" width="200" height="100" label="create popup" 
                      click="button_clickHandler(event)" /> 
        </s:Panel>

        <s:TitleWindow id="titleWin"
                       title="Spark TitleWindow"
                       close="titleWin_closeHandler(event);"
                       width="300">
            <s:layout>
                <s:VerticalLayout paddingLeft="10" paddingRight="10"
                                  paddingTop="10" paddingBottom="10" />
            </s:layout>
            <s:Label text="Popup window"
                     fontSize="24"
                     width="100%"/>
        </s:TitleWindow>
    </fx:Declarations>
</s:Application>

Answer 3

如果您的所有元素都在同一个MXML文件中，则只需将s:Group元素放在文件底部作为其最后一个元素。

如果您的视图更动态地连接，那么您可以使用以下内容强制其索引：

var topIndex:int = myParentView.numChildren - 1;
myParentView.setChildIndex(myGroupElement, topIndex);

如果myGroupElement引用s:Group或其ID，则myGroupElement。

myParentView在执行此代码时必须已是s:Group的孩子。

如果您的Popup元素仅偶尔显示，您可能会对{{1}}感兴趣。

TitleWindow顶部的Flex 4组件

3 个答案: