Question

我遇到了OpenMP和共享变量的问题，我无法理解。我所做的一切都在Fortran 90/95中。

这是我的问题：我在main程序中定义了一个并行区域，其中包含DEFAULT(SHARED)子句，我在其中调用了一个执行某些计算的子程序。我有一个我分配的局部变量（数组），我在其上进行计算。我期待这个数组被共享（因为DEFAULT(SHARED)子句），但似乎并非如此。

这是我正在尝试做的一个例子，它重现了我得到的错误：

program main
  !$ use OMP_LIB
  implicit none

  integer, parameter :: nx=10, ny=10
  real(8), dimension(:,:), allocatable :: array

  !$OMP PARALLEL DEFAULT(SHARED)
  !$OMP SINGLE
  allocate(array(nx,ny))
  !$OMP END SINGLE

  !$OMP WORKSHARE
  array = 1.
  !$OMP END WORKSHARE

  call compute(array,nx,ny)

  !$OMP SINGLE
  deallocate(array)
  !$OMP END SINGLE
  !$OMP END PARALLEL

contains
  !=============================================================================
  ! SUBROUTINES
  !=============================================================================
  subroutine compute(array, nx, ny)
    !$ use OMP_LIB
    implicit none

    real(8), dimension(nx,ny) :: array
    integer :: nx, ny
    real(8), dimension(:,:), allocatable :: q
    integer :: i, j

    !$OMP SINGLE
    allocate(q(nx,ny))
    !$OMP END SINGLE

    !$OMP WORKSHARE
    q = 0.
    !$OMP END WORKSHARE

    print*, 'q before: ', q(1,1)

    !$OMP DO SCHEDULE(RUNTIME)
    do j = 1, ny
       do i = 1, nx
          if(mod(i,j).eq.0) then
             q(i,j) = array(i,j)*2.
          else
             q(i,j) = array(i,j)*0.5
          endif
       end do
    end do
    !$OMP END DO

    print*, 'q after: ', q(1,1)

    !$OMP SINGLE
    deallocate(q)
    !$OMP END SINGLE

  end subroutine compute
  !=============================================================================
end program main

当我这样执行时，我得到一个分段错误，因为本地数组q分配在一个线程上但不分配在其他线程上，当其他线程尝试在内存中访问它时，它会崩溃。

如果我摆脱SINGLE区域，则会分配本地数组q（尽管有时会崩溃，这是有意义的，如果不同的线程尝试分配它，而情况已经如此（和实际上它让我感到困惑，为什么它不会每次都崩溃））但是它显然好像数组q是私有的（因此一个线程返回我预期值，而其他线程返回给我其他东西）。

虽然我用q声明了我的并行区域，但为什么DEFAULT(SHARED)数组不被共享真的让我很困惑。因为我处于一个孤立的子程序中，所以我不能明确地声明q共享，因为它仅在子程序compute中被知道...到目前为止我一直困在这个问题，我找不到解决方法。

这是正常的吗？我应该期待这种行为吗？有解决方法吗？我会错过一些明显的东西吗？

任何帮助都将受到高度赞赏！

Answer 1

q是一个实体，就OpenMP说而言，“在一个区域内，但不在一个构造内”。 q本地的子例程位于并行构造期间调用的过程中，但q本身不会在PARALLEL和END PARALLEL指令之间出现。

然后，OpenMP中此类实体的数据共享规则规定q是私有的。

数据共享子句（如DEFAULT（SHARED）等）仅适用于构造本身中出现的内容（词汇表出现在PARALLEL和END PARALLEL之间）。（它们通常不适用于该地区的事物 - 该地区调用的程序可能已经单独编译，可能在任何并行结构之外调用。）

Answer 2

数组q在被调用的子程序中定义。每个线程都独立调用这个子程序，因此每个线程都有自己的副本。外部子例程中的shared指令无法更改此设置。尝试使用save属性声明它。

Fortran中的OpenMP和共享变量，不共享

2 个答案: