Question

我有一个名为* MIS的多个文件的目录。现在这些文件包含重复的行。我需要读取名为VIA的目录中名为* _MIS＆amp;的所有文件。删除重复行后更新文件（需要排序-u）。需要使用TCL

Answer 1

如果您在纯Tcl中执行此操作，则应将任务拆分为两部分：一个用于对文件进行排序的部分（将执行一个很好的过程）以及一个对目录中的所有相关文件进行排序的部分： / p>

proc sort_file {filename} {
    # Read the file
    set f [open $filename]
    set data [read $f]
    close $f

    # Sort the lines, removing dupes
    set lines [split $data "\n"]
    set sorted_uniques [lsort -unique $lines]
    set data [join $sorted_uniques "\n"]

    # Write the file
    set f [open $filename w]
    puts $f $data
    close $f
}

# Now process all the relevant files; the -directory option is a convenient way
# to specify which directory to do the searching in.
foreach filename [glob -directory VIA *_MIS] {
    sort_file $filename
}

解决方案的关键部分：lsort -unique和foreach / glob。

Answer 2

您可以尝试以下

set dir_path path_to_directory_contains_MIS_files
set files_list [glob -directory $dir_path *_MIS]
foreach mis_file $files_list {
    if {[catch {exec sort -u $mis_file -o $mis_file} result]} {
        puts "ERROR: $result"
    } 
}

tcl对文件进行排序

2 个答案: