Question

我正在尝试使用DBD::Mock来测试使用数据库的代码。到目前为止，正常的SQL查询工作得很好，但是我对如何测试调用存储过程的代码感到有些不知所措。使用bound_params构造函数的DBD::Mock::Session->new键，我可以指定输入参数，但我似乎无法找到一种方法来设置使用DBI::StatementHandle::bind_param_inout()绑定的参数的模拟结果

要提供将要测试的代码的示例，请查看以下内容：

use DBI;
my $dbh = DBI->connect('dbi:Mock', '', '', { RaiseError => 1, PrintError => 1 });
my $sth = $dbh->prepare(q{
BEGIN
  some_stored_proc(i_arg1 => :arg1, o_arg2 => :arg2);
END;
});
my ($arg1, $arg2) = ('foo', 'bar');
$sth->bind_param(':arg1', $arg1);
$sth->bind_param_inout(':arg2', \$arg2, 200);
$sth->execute();
print STDERR "OUTPUT VALUE OF arg2 = $arg2\n";

现在，我想使用'frobnication'为arg2参数设置数据库，以便在执行上述代码时，$arg2变量包含此字符串，输出为< / p>

输出值arg2 = frobnication

Answer 1

这是我最终做的事情。基本上，主要工作涉及覆盖DBD::Mock::st::bind_param_inout方法。

use DBI;
use DBD::Mock;
use DBD::Mock::st;
use Carp;

# array of values to be bound on each invocation
my @values = qw/frobnication/;
# dummy variable to trick DBD::Mock into thinking it got the same reference for
# bind_param_inout and bound_params (the former is usually not in the control of
# the testing code, hence this hack).
my $dummy = undef;
# keep reference to the original bind_param_inout method
my $bind_param_inout_orig = \&DBD::Mock::st::bind_param_inout;
# override with our mocked version that assigns a value to the reference.
# notice that it does so at the bind_param_inout call, *NOT* the execute call!
local *DBD::Mock::st::bind_param_inout = sub {
  my ($self, $param_num, $val, $size) = (shift, shift, shift, shift);
  $bind_param_inout_orig->($self, $param_num, \$dummy, $size, @_);
  $$val = shift @values or Carp::confess '@values array exhausted!';
};

# set up the mock session
my $dbh = DBI->connect('dbi:Mock:', '', '',
  { RaiseError => 1, PrintError => 1 });
$dbh->{mock_session} = DBD::Mock::Session->new('foo_session' => (
  {
    statement => qr/BEGIN\n\s*some_stored_proc/,
    results => [],
    bound_params => ['foo', \$dummy]
  }));

# this is the code to be tested

my $sth = $dbh->prepare(q{
BEGIN
  some_stored_proc(i_arg1 => :arg1, o_arg2 => :arg2);
END;
});
my ($arg1, $arg2) = ('foo', 'bar');
$sth->bind_param(':arg1', $arg1);
$sth->bind_param_inout(':arg2', \$arg2, 200);
$sth->execute();
print STDERR "OUTPUT VALUE OF arg2 = $arg2\n";

Answer 2

您可以使用Sub::Override覆盖此子目录。

您可以像这样修改您的模拟对象并创建一个新的模拟子。

$mocked_dbd->mock( 'bind_param_inout',&mocked_bind_param_inout );

我觉得这个方法在这里被嘲笑：http://cpansearch.perl.org/src/DICHI/DBD-Mock-1.45/lib/DBD/Mock/st.pm

也许这会奏效：

my @rs_foo = (
    [ 'this', 'that' ],
    [ 'this_one', 'that_one' ],
    [ 'this_two', 'that_two' ],
);
# the first one ordered
$dbh->{mock_add_resultset} = [ @rs_foo ];

use Data::Dumper;
my $mocked_records = $sth->{mock_records};
print Dumper($mock_records);

DBD :: Mock指定存储过程的输出值

2 个答案: