Question

是否可以有条件地将文件/文件夹和安装选项添加到NSIS安装程序？我的想法是如果文件夹 Foo 存在于给定位置，则应将其添加到安装程序中并添加安装 Foo 的选项安装程序也是如此。但是如果文件夹 Foo 不存在，NSIS脚本应该只创建安装程序，但保留 Foo 并从中选择 Foo 的选项

Answer 1

您可以尝试添加/NONFATAL的文件。如果存在，编译器将包含它。在运行时，您可以检查安装程序是否能够提取它。

File /NONFATAL "file.zip"
${If} ${FileExists}  "$OUTDIR\file.zip"
...
${EndIf}

Answer 2

在NSIS 2中File /NONFATAL /R "c:\foo"是没有外部工具的最佳选择，当没有文件时你需要一点点黑客来隐藏该部分：

!include LogicLib.nsh
Page Components
Page InstFiles

Section "Main"
SetOutPath $InstDir
# File "C:\myfiles\myapp.exe"
SectionEnd

Section "Install Foo" SID_FOO
SetOutPath $InstDir
File /NONFATAL /r "C:\myfiles\foo\*.*"
SectionEnd

Function .onInit
SectionGetSize ${SID_FOO} $0
StrCmp $0 0 "" +3
SectionSetFlags ${SID_FOO} 0 ; Force all flags off including the checkmark
SectionSetText ${SID_FOO} "" ; Hide the section because its size is 0
FunctionEnd

如果这是不可接受的，您可以使用!system并从cmd.exe获得一些帮助以检查是否存在某些内容：

!tempfile INCEXIST
!system 'if exist "C:\myfiles\foo\*.*" echo !define HAVE_FOO > "${INCEXIST}"'
!include "${INCEXIST}"
!delfile "${INCEXIST}"
!ifdef HAVE_FOO
Section "Install Foo"
SetOutPath $InstDir
File /r "C:\myfiles\foo\*.*"
SectionEnd
!endif

在NSIS 3 !if支持/ FileExists开关：

!if /FileExists "C:\myfiles\foo\*.*"
Section "Install Foo"
SetOutPath $InstDir
File /r "C:\myfiles\foo\*.*"
SectionEnd
!endif

Answer 3

替换文件的示例取决于正在运行的服务并且在targget位置是否存在

    IfFileExists "$SYSDIR\my_file.dll" exist notexist

exist:
ExecWait 'net stop desired_service'

SetOutPath $SYSDIR
SetOverwrite on

File "/oname=$SYSDIR\my_file.dll" "Path to my file\my_file.dll"

ExecWait 'net start desired_service'

notexist:
.....what you want to do if doesn't exists

是否可以有条件地将文件/文件夹添加到NSIS安装程序

3 个答案: