Question

输入文件1：

5 5 NA
NA NA 1
2 NA 2

输入文件2：

1 1 1
2 NA 2
3 NA NA
NA 4 4
5 5 5
NA NA 6

输出：

3 NA NA
NA 4 4
NA NA 6

目的是：在file1中，将每行不是NA的任何项设置到一个集合中，然后在file2中，消除其字段在此集合中的行。有没有人有这方面的想法？

Answer 1

要添加任何项而不是'NA'：

awk -f script.awk file1 file2

script.awk的内容：

FNR==NR {
    for (i=1;i<=NF;i++) {
        if ($i != "NA") {
            a[$i]++
        }
    }
    next
}

{
    for (j=1;j<=NF;j++) {
        if ($j in a) {
            next
        }
    }
}1

结果：

3 NA NA
NA 4 4
NA NA 6

或者，这是单行：

awk 'FNR==NR { for (i=1;i<=NF;i++) if ($i != "NA") a[$i]++; next } { for (j=1;j<=NF;j++) if ($j in a) next }1' file1 file2

Answer 2

您可以使用grep执行此操作：

$ egrep -o '[0-9]+' file1 | fgrep -wvf - file2
3 NA NA
NA 4 4
NA NA 6

Answer 3

awk one-liner：

awk 'NR==FNR{for(i=1;i<=NF;i++)if($i!="NA"){a[$i];break} next}{for(i=1;i<=NF;i++)if($i in a)next;}1' file1 file2

包含您的数据：

kent$  awk 'NR==FNR{for(i=1;i<=NF;i++)if($i!="NA"){a[$i];break;} next}{for(i=1;i<=NF;i++)if($i in a)next;}1' file1 file2
3 NA NA
NA 4 4
NA NA 6

Answer 4

如果值的列位置很重要：

awk '
  NR==FNR{
    for(i=1; i<=NF; i++) if($i!="NA") A[i,$i]=1
    next
  }
  {
    for(i=1; i<=NF; i++) if($i!=NA && A[i,$i]) next
    print 
  }
' file1 file2

如何在awk或shell中实现它？

4 个答案: