Question

我正在使用TXMLDocument来解析XML文档（来自文件或内存），并在树视图中显示它。有没有办法在XML内容中获取XMLNode的字符位置和长度？我想突出显示原始文档中的节点文本，或者当用户在树中选择其等效节点时，或者当该节点存在奇怪的东西时，如空值，错误文本等。

我读了this article，但我不确定如何在Delphi中实现它。

Answer 1

唯一可以提供此信息的类是XML解析器。我不知道TXMLDocument是否这样做（我找不到任何东西）。但是文件中的确切位置可能存在问题。通常，XML文档可以是脏文件，需要一些格式才能显示。如果是这样，问题会在格式化后更改以确定节点的位置。这样做更容易一些，因为您可以使用相同的数据（IXMLNode）来填充树并显示格式化的XML。

我使用FormatXMLData在RichEdit中显示XML，并使用here中的DomToTree来填充树。我更改了DomToTree以保留每个节点的行索引。它出来是这样的：

procedure TForm1.DomToTree (XmlNode: IXMLNode; TreeNode: TTreeNode;
  var CurrentLineIndex: Integer); // <--- added this parameter
var
  I: Integer;
  NewTreeNode: TTreeNode;
  NodeText: string;
  AttrNode: IXMLNode;
begin
  // skip text nodes and other special cases
  if XmlNode.NodeType <> ntElement then
    Exit;
  // add the node itself
  NodeText := XmlNode.NodeName;
  if XmlNode.IsTextElement then
    NodeText := NodeText + '=' + XmlNode.NodeValue;
  NewTreeNode := TreeView1.Items.AddChildObject(TreeNode, NodeText, Pointer(CurrentLineIndex));
  // add attributes
  for I := 0 to xmlNode.AttributeNodes.Count - 1 do
  begin
    AttrNode := xmlNode.AttributeNodes.Nodes[I];
    TreeView1.Items.AddChildObject(NewTreeNode,
      '[' + AttrNode.NodeName + '="' + AttrNode.Text + '"]', Pointer(CurrentLineIndex));
  end;
  Inc(CurrentLineIndex);
  // add each child node
  if XmlNode.HasChildNodes then
  begin
    for I := 0 to xmlNode.ChildNodes.Count - 1 do
    begin
      DomToTree (xmlNode.ChildNodes.Nodes[I], NewTreeNode, CurrentLineIndex);
    end;
    Inc(CurrentLineIndex);
  end;
end;

现在我可以在RichEdit中突出显示所选节点的等效文本：

procedure TForm1.TreeView1Change(Sender: TObject; Node: TTreeNode);
var
  LineIndex, TextPos: Integer;
  Text: string;
begin
  SetSelBgColor(RichEdit1, clWhite);
  LineIndex := Integer(Node.Data);
  TextPos := RichEdit1.Perform(EM_LINEINDEX, LineIndex, 0);
  Text := Node.Text;
  Text := ReplaceStr(Text, '[', '');
  Text := ReplaceStr(Text, ']', '');

  RichEdit1.SelStart := TextPos + Pos(Text, RichEdit1.Lines[LineIndex]) - 1;
  RichEdit1.SelLength := Length(Text);
  SetSelBgColor(RichEdit1, clYellow);
end;

整个事情就是这样开始的：

procedure TForm1.Button1Click(Sender: TObject);
var
  FirstLineIndex: Integer;
begin
  with TOpenDialog.Create(Self) do
  begin
    if Execute then
    begin
      XMLDocument1.LoadFromFile(FileName);
      Treeview1.Items.Clear;
      FirstLineIndex := 1;
      DomToTree (XMLDocument1.DocumentElement, nil, FirstLineIndex);
      TreeView1.FullExpand;
      RichEdit1.Lines.Text := FormatXMLData(XMLDocument1.XML.Text);
    end;
    Free;
  end;
end;

但是，由于DomToTree和FormatXMLData无法正常工作，因此不是预期的保证代码。我用一些文件测试了代码，但很多都失败了。最好的方法是重写它们。但是如果你想测试代码，它可以用这样的东西：

<?xml version="1.0" standalone="yes"?>
<DATAPACKET Version="2.0">
  <METADATA>
    <FIELDS>
      <FIELD attrname="ClientDataSet1FieldCode" fieldtype="i4"/>
      <FIELD attrname="ClientDataSet1FieldContact" fieldtype="string" WIDTH="50"/>
      <FIELD attrname="ClientDataSet1FieldNoTell" fieldtype="string" WIDTH="15"/>
    </FIELDS>
    <PARAMS CHANGE_LOG="1 0 4"/>
  </METADATA>
  <ROWDATA>
    <ROW RowState="4" ClientDataSet1FieldCode="1" ClientDataSet1FieldContact="Ali" ClientDataSet1FieldNoTell="012345678"/>
  </ROWDATA>
</DATAPACKET>

如何确定XML文档中XMLNode的位置？

1 个答案: