Question

通过Project Euler尝试学习F＃，我在为problem 3编写解决方案时偶然发现了类似推断问题。

这是我写的：

let rec findLargestPrimeFactor p n = 
    if n = 1 then p
    else
        if n % p = 0 then findLargestPrimeFactor p (n/p)
        else findLargestPrimeFactor (p+1) n

let result = findLargestPrimeFactor 2 600851475143L

但是，编译器给出了以下错误：

error FS0001: This expression was expected to have type    int    but here has type    int64

由于我希望从findLargestPrimeFactor中推断使用的类型，我很惊讶地发现编译器似乎假设参数n是一个int，因为在唯一的调用中该函数使用int64完成。

有人可以向我解释一下：

为什么编译器似乎对类型
如何解决此限制

Answer 1

findLargestPrimeFactor中的类型是从使用情况推断出来的。 F＃编译器以自上而下的方式执行类型推断，因此p和n（findLargestPrimeFactor的参数）的类型是从它们在函数中的用法推断出来的。当编译器看到let result = ...时，参数类型已被推断为int。

最简单的解决方案是在所有常量值上使用L后缀，因此类型将推断为int64：

let rec findLargestPrimeFactor p n = 
    if n = 1L then p
    else
        if n % p = 0L then findLargestPrimeFactor p (n/p)
        else findLargestPrimeFactor (p + 1L) n

let result = findLargestPrimeFactor 2L 600851475143L

如果您想要更高级的解决方案，可以使用LanguagePrimitives模块中的通用一和零常量。这允许findLargestPrimeFactor是通用的（-ish），因此可以使用不同的数字类型更轻松地重用它：

open LanguagePrimitives

let rec findLargestPrimeFactor p n = 
    if n = GenericOne then p
    else
        if n % p = GenericZero then findLargestPrimeFactor p (n/p)
        else findLargestPrimeFactor (p + GenericOne) n

(* You can use one of these, but not both at the same time --
   now the types of the _arguments_ are used to infer the types
   of 'p' and 'n'. *)

//let result = findLargestPrimeFactor 2L 600851475143L
let result = findLargestPrimeFactor 2 Int32.MaxValue

Per @kvb的建议，以下是一般编写此函数的方法：

open LanguagePrimitives

let inline findLargestPrimeFactor p n =
    let rec findLargestPrimeFactor p n =
        if n = GenericOne then p
        else
            if n % p = GenericZero then findLargestPrimeFactor p (n/p)
            else findLargestPrimeFactor (p + GenericOne) n
    findLargestPrimeFactor p n

(* Now you can call the function with different argument types
   as long as the generic constraints are satisfied. *)
let result = findLargestPrimeFactor 2L 600851475143L
let result' = findLargestPrimeFactor 2 Int32.MaxValue

F＃在实际处理int64时假设为int

1 个答案: