Question

我无法在网上找到任何好的例子。

有人可以展示如何从groovy运行存储过程（返回多个结果集）吗？

基本上我只是想确定存储过程返回多少个结果集..

Answer 1

我编写了一个帮助程序，它允许我使用存储过程来返回单个ResultSet，其方式类似于使用groovy.sql.Sql的查询。这可以很容易地适用于处理多个ResultSet（我假设每个ResultSet都需要它自己的闭包）。

用法：

Sql sql = Sql.newInstance(dataSource)
SqlHelper helper = new SqlHelper(sql);
helper.eachSprocRow('EXEC sp_my_sproc ?, ?, ?', ['a', 'b', 'c']) { row ->
    println "foo=${row.foo}, bar=${row.bar}, baz=${row.baz}"
}

代码：

class SqlHelper {
    private Sql sql;

    SqlHelper(Sql sql) {
        this.sql = sql;
    }

    public void eachSprocRow(String query, List parameters, Closure closure) {
        sql.cacheConnection { Connection con ->
            CallableStatement proc = con.prepareCall(query)
            try {
                parameters.eachWithIndex { param, i ->
                    proc.setObject(i+1, param)
                }

                boolean result = proc.execute()
                boolean found = false
                while (!found) {
                    if (result) {
                        ResultSet rs = proc.getResultSet()
                        ResultSetMetaData md = rs.getMetaData()
                        int columnCount = md.getColumnCount()
                        while (rs.next()) {
                            // use case insensitive map
                            Map row = new TreeMap(String.CASE_INSENSITIVE_ORDER)
                            for (int i = 0; i < columnCount; ++ i) {
                                row[md.getColumnName(i+1)] = rs.getObject(i+1)
                            }
                            closure.call(row)
                        }
                        found = true;
                    } else if (proc.getUpdateCount() < 0) {
                        throw new RuntimeException("Sproc ${query} did not return a result set")
                    }
                    result = proc.getMoreResults()
                }
            } finally {
                proc.close()
            }
        }
    }
}

Answer 2

所有Java类都可以从Groovy中使用。如果Groovy没有给你一个方法，那么你可以使用JDBC callable statements以Java方式进行。

Answer 3

我只是偶然发现了可能解决问题的方法，如果您的例子就是您所追求的，请查看the reply to this thread

如何从groovy运行存储过程，返回多个结果集

3 个答案: