Question

我正在构建一个RSS提要，但是出现了以下部分的问题：

<description>
<![CDATA[
<img src="http://l.yimg.com/a/i/us/we/52/34.gif"/><br /> <b>Current Conditions:</b><br /> Fair, 73 F<BR /> <BR /><b>Forecast:</b><BR /> Sat - Clear. High: 78 Low: 62<br /> Sun - Mostly Sunny. High: 80 Low: 66<br /> <br /> <a href="http://us.rd.yahoo.com/dailynews/rss/weather/Dubai__AE/*http://weather.yahoo.com/forecast/AEXX0004_f.html">Full Forecast at Yahoo! Weather</a><BR/><BR/> (provided by <a href="http://www.weather.com" >The Weather Channel</a>)<br/>
]]>
</description>

您可以看到我的尝试here

这是我的XSLT：

<?xml version="1.0" encoding="iso-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/">
<html>
  <head>
    <title></title>
  </head>
  <body>
    <table cellpadding="2" cellspacing="0" border="0" width="75%">
        <xsl:for-each select="rss/channel/item">

              <tr style="color:#0080FF;">
                <td style="text-align:left;font-weight:bold;">
                  <xsl:value-of select ="title"></xsl:value-of>
                </td>
                </tr>


                <tr style="color:#0080FF;">
                <td style="text-align:left;font-weight:bold;">
                  <xsl:value-of select ="location"></xsl:value-of>
                  <xsl:value-of select="pubDate"/>
                </td>
              </tr>


              <tr>
                <td colspan="2" style="text-align:left;padding-top:10px;">
                  <xsl:value-of select="description"/>
                </td>
              </tr>

          <tr>
            <td colspan="2" style="height:20px;">
              <hr></hr>
            </td>
          </tr>
        </xsl:for-each>
    </table>
  </body>
</html>
 </xsl:template>
</xsl:stylesheet>

我正在尝试从描述标签中获取信息，因此我可以像设置标题和发布日期那样设置样式。 Here是我想要设计的完整XML RSS提要。任何人都可以帮我弄明白为什么CDATA标签搞砸了吗？

Answer 1

尽量不要使用<xsl:for-each>。当您依赖<xsl:template>和<xsl:apply-templates>时，代码会更清晰地排列。

还尝试使用CSS类并从输出HTML中删除内联样式。

如果输出经典HTML（不是XHTML），那么告诉XSLT处理器使用<xsl:output>并输出doctype。

您的输出问题将通过disable-output-escaping="yes"解决。请注意，并非每个XSL处理器都支持该属性。根据XSLT规范，禁用输出转义的功能是可选的。

<xsl:stylesheet 
  version="1.0" 
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
>
  <xsl:output method="html" indent="yes" 
     doctype-system='http://www.w3.org/TR/html4/strict.dtd'
     doctype-public='-//W3C//DTD HTML 4.01//EN' 
  />

  <xsl:template match="/rss">
    <html>
      <head>
        <title></title>
      </head>
      <body>
        <xsl:apply-templates select="channel" />
      </body>
    </html>
  </xsl:template>

  <xsl:template match="channel">
    <table cellpadding="2" cellspacing="0" border="0" width="75%">
      <xsl:apply-templates select="item" />
    </table>
  </xsl:template>

  <xsl:template match="item">
    <!-- ... -->
    <tr>
      <td colspan="2" style="text-align:left;padding-top:10px;">
        <xsl:value-of select="description" disable-output-escaping="yes" />
      </td>
    </tr>
    <!-- ... -->
  </xsl:template>
</xsl:stylesheet>

使用XSLT设置RSS提要样式，CDATA标记问题

1 个答案: