Question

我有一个XML文档，它构成了自动REST测试步骤的一部分。我需要将步骤克隆大约一千次，但文档中有一个键值需要对每个克隆都是唯一的。什么是最好的方法 - 脚本，工具或其他什么，我可以用它来反复复制它但是为每个实例更改一个值？我想过尝试编写一个java程序来做这个，但我没有在java中处理XML的经验，我的理解是解析很痛苦。

更新：目前正在调查XSLT以及它是否符合这一需求。如果您有任何意见或建议，请分享。

Answer 1

XSLT 2.0对此没问题。（如果您需要XSLT 2.0处理器，我建议Saxon。）

例如，这个简单的XML文档：

<doc>
    <foo/>
    <bar id="orig-id"/>
</doc>

和这个XSLT 2.0样式表：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:param name="threshold" select="10"/>

    <xsl:template match="@*|node()" mode="clone">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()" mode="clone"/>          
        </xsl:copy>
    </xsl:template>

    <xsl:template match="/*/bar/@id" mode="clone">
        <xsl:param name="doc-id" tunnel="yes"/>
        <xsl:attribute name="id" select="$doc-id"/> 
    </xsl:template>

    <xsl:template match="/" name="createDocs">
        <xsl:param name="dashNbr" select="1"/>
        <xsl:variable name="doc-id" select="concat(generate-id(),'-',$dashNbr)"/>
        <xsl:result-document href="{$doc-id}.xml">
            <xsl:apply-templates select="/*" mode="clone">
                <xsl:with-param name="doc-id" select="$doc-id" tunnel="yes"/>
            </xsl:apply-templates>          
        </xsl:result-document>
        <xsl:if test="$threshold > $dashNbr">
            <xsl:call-template name="createDocs">
                <xsl:with-param name="dashNbr" select="$dashNbr + 1"/>
            </xsl:call-template>
        </xsl:if>
    </xsl:template>

</xsl:stylesheet>

生成10个具有唯一id属性的文件。文件名基于id。

示例：

d1-1.xml

<doc>
   <foo/>
   <bar id="d1-1"/>
</doc>

d1-2.xml

<doc>
   <foo/>
   <bar id="d1-2"/>
</doc>

d1-10.xml

<doc>
   <foo/>
   <bar id="d1-10"/>
</doc>

您只需要将threshold参数的值更改为您想要创建的文件数，并更改要修改的属性的match。

需要使用不断增加的值多次克隆XML文档

1 个答案: