Question

我正在prolog编写一个扫描数字列表的作业，并且应该返回列表是否是有效的罗马数字和数字的十进制值。例）

1 ?- roman(N, ['I'], []).
N = 1
true.

2 ?-

当我运行我觉得应该工作的程序时，十进制值总是正确的，所以我猜我的合成属性部分是正确的，但是对于应该返回true的数字列表它总是返回false。我还想补充一点，如果超过3个是Is，Xs或Cs，它就会中止。

1 ?- roman(N, ['I'], []).
N = 1 ;
false.

2 ?- roman(N, ['I','I','I','I'], []).
Error: too many I's
% Execution Aborted
3 ?-

当我取出N并投入{write('N = '), write(N)}时，它可以正常工作并返回true。

1 ?- roman(['I'], []).
N = 1
true.

当我删除{N is ValH + ValT + ValU}时，它返回true，但它不再显示小数值。这是我的代码的第一行（因为这是一个当前的作业，我更愿意尽可能少地显示以获得答案）：

roman(N) --> hundreds(ValH), tens(ValT), units(ValU), {N is ValH + ValT + ValU}.

为什么N会返回false，但是没有，我该如何解决？

分配： 以下BNF规范定义了罗马数字的语言少于1000：

<roman> ::= <hundreds> <tens> <units>
<hundreds> ::= <low hundreds> | CD | D <low hundreds> | CM
<low hundreds> ::= e | <low hundreds> C
<tens> ::= <low tens> | XL | L <low tens> | XC
<low tens> ::= e | <low tens> X
<units> ::= <low units> | IV | V <low units> | IX
<low units> ::= e | <low units> I

定义此语法的属性以执行两项任务：

a）限制<low tens>中的X的数量，<low units>中的I，以及 <low hundreds>中的C不超过三个。

b）提供<roman>的属性，该属性给出了小数点罗马数字被定义。

定义这些任务所需的任何其他属性，但不要更改 BNF语法。

Answer 1

您是否注意到语法是由相同的模式（组// 5）重复形成3次，只是使用不同的符号？我喜欢紧凑......

roman(N) -->
    group('C','D','M',100, H),
    group('X','L','C',10, T),
    group('I','V','X',1, U),
    {N is H+T+U}.
group(A,B,C, Scale, Value) -->
    (   g3(A, T)
    ;   [A, B], {T = 4}
    % thanks to Daniel and Will for catching bugs
    ;   [B], g3(A, F), {T is 5+F}
    ;   [B], {T is 5}
    ;   [A, C], {T = 9}
    ;   {T = 0}
    ),  {Value is Scale * T}.


g3(C, 1) --> [C].
g3(C, 2) --> [C,C].
g3(C, 3) --> [C,C,C].

一些测试

?- atom_chars('CMXXX',L), phrase(roman(N),L).
L = ['C', 'M', 'X', 'X', 'X'],
N = 930 ;
false.

?- atom_chars('CMXLVIII',L), phrase(roman(N),L).
L = ['C', 'M', 'X', 'L', 'V', 'I', 'I', 'I'],
N = 943 ;
false.

只是好奇，让DCG在工作......

丹尼尔和威尔评论之后

编辑 ......

?- atom_chars('VIII',L), phrase(roman(N),L).
L = ['V', 'I', 'I', 'I'],
N = 8 .

?- phrase(roman(X), ['L','I','X']).
X = 59 .

Prolog罗马数字（属性语法）

1 个答案: