Question

我刚刚检查了stackoverflow，它似乎非常有用并且在Windows XP上运行良好。但是使用Windows 7它并不适用于某些不明原因。

PATH变量看起来像这样

C:\Program Files (x86)\NVIDIA Corporation\PhysX\Common;C:\Windows\system32;C:\Windows;C:\Windows\System32\Wbem;C:\Windows\System32\WindowsPowerShell\v1.0\;C:\Program Files (x86)\QuickTime\QTSystem\

它显然包含\以及我用于分割包含此FOR循环的批处理的分号：

   FOR /F "delims=;" %%A IN ("%PATH%") DO (
      echo %%A
   )

执行不会导致任何错误，但只提供一个（第一个）令牌

C:\Program Files (x86)\NVIDIA Corporation\PhysX\Common

我不知道为什么FOR终止并玩弄网上建议的几个变种，但没有人完成这项工作。

任何帮助都将受到高度赞赏。

基督教

Answer 1

你可以这样做。

for %%A in ("%path:;=";"%") do (
    echo %%~A
)

（Source）

您拥有它的方式的问题在于，使用for /F开关，%%A仅指定第一个标记。您必须执行for /f "tokens=1-9 delims=;" %%A in ("%PATH%")并通过%%A通过%%I方式阅读。

Answer 2

结合在此和其他各种stackoverflow页面上学到的东西，OP可以扩展到：

如何确保PATH变量具有唯一值？

使用数组变量可以这样做：

REM usage: call :make_path_unique VARNAME "%VARNAME%"
REM 1: splits VARNAME on ';' and builds an array of unique values (case insensitive)
REM 2: glues the array back into a single variable
REM 3: set the VARNAME to this newly unique-ified collection.
REM
REM From: various StackOverflow pages:
REM     http://stackoverflow.com/questions/5471556/pretty-print-windows-path-variable-how-to-split-on-in-cmd-shell
REM     http://stackoverflow.com/questions/3262287/make-an-environment-variable-survive-endlocal
REM     http://stackoverflow.com/questions/14879105/windows-path-variable-how-to-split-on-in-cmd-shell-again
REM
:make_path_unique
  setlocal EnableDelayedExpansion
  set VNAME=%~1
  set VPATH=%~2
  set I=0
  for %%A in ("%VPATH:;=";"%") do (
    set FOUND=NO
    for /L %%B in (1,1,!I!) do (
        if /I "%%~A"=="!L[%%B]!" set FOUND=YES
    )
    if NO==!FOUND! (
        set /A I+=1
        set L[!I!]=%%~A
    )
  )
  set FINAL=!L[1]!
  for /L %%n in (2,1,!I!) do (
    set FINAL=!FINAL!;!L[%%n]!
    set L[%%n]=
  )
  for %%P in ("!FINAL!") do (
    endlocal
    set %VNAME%=%%~P
  )
  exit /b 0

步骤摘要：

for循环拆分PATH在＆＃39 ;;＆＃39;并妥善管理报价
1. for循环查看所有先前存储的路径
2. 仅扩展数组
将阵列包粘在一起，随时清除数组变量
替换路径并清除临时变量
从函数返回，没有错误。

引用了：

set PATH=%PATH%;%MY_PATH_ADDITIONS%
call :make_path_unique PATH "%PATH%"

windows％PATH％变量 - 如何拆分';'再次在CMD shell中

2 个答案: