XSLT将元素从源复制到CDATA部分

时间：2013-02-13 10:19:58

标签： xml xslt soap namespaces cdata

我正在将简单的SOAP XML消息转换为更加扩展的SOAP XML消息。我几乎可以使用它，但我无法解决最后两个问题。我的问题是：

  1. 元素后面的所有元素都应位于CDATA部分。我尝试使用'cdata-section-elements'，但无法使其正常工作。
  2. 元素应该如下所示

    3. 我的源XML文件：

    <?xml version="1.0" encoding="utf-8"?>
<SOAP-ENV:Envelope xmlns:SOAP-ENV="http://schemas.xmlsoap.org/soap/envelope/">
  <SOAP-ENV:Header/>
  <SOAP-ENV:Body>
    <test>
      <element1>123</element1>
      <element2>123</element2>
    </test>
  </SOAP-ENV:Body>
</SOAP-ENV:Envelope>

    我的XSLT：

    <?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:fn="http://www.w3.org/2005/xpath-functions" xmlns:SOAP-ENV="http://schemas.xmlsoap.org/soap/envelope/" exclude-result-prefixes="fn xs SOAP-ENV">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes" />

<!-- Special rule to match the document root only -->
<xsl:template match="/*">
    <s:Envelope xmlns:s="http://www.w3.org/2003/05/soap-envelope">
        <xsl:namespace name="a" select="'http://www.w3.org/2005/08/addressing'"/>
        <xsl:apply-templates select="@*|node()"/>
    </s:Envelope>
</xsl:template>

<!-- Expand soap header -->
<xsl:template match="SOAP-ENV:Header">
    <xsl:element name="s:{local-name()}" namespace="http://www.w3.org/2003/05/soap-envelope">
        <xsl:element name="a:Action" namespace="http://www.w3.org/2005/08/addressing">
            <xsl:attribute name="s:mustUnderstand" namespace="http://www.w3.org/2003/05/soap-envelope">1</xsl:attribute>
            <xsl:text>http://www.ortec.com/CAIS/IApplicationIntegrationService/SendMessage</xsl:text>
        </xsl:element>
    </xsl:element>
</xsl:template>

<!-- Change soap body -->
<xsl:template match="SOAP-ENV:Body">
    <xsl:element name="s:{local-name()}" namespace="http://www.w3.org/2003/05/soap-envelope">
        <xsl:element name="cais:SendMessage" namespace="http://www.ortec.com/CAIS">
            <xsl:element name="cais:message" namespace="http://www.ortec.com/CAIS">
                <!-- copy the rest -->
                <xsl:apply-templates select="child::node()"/>
            </xsl:element>
            <xsl:element name="cais:commandName" namespace="http://www.ortec.com/CAIS">Import</xsl:element>
        </xsl:element>
    </xsl:element>
</xsl:template>

<!-- template for the copy of the rest -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>
</xsl:stylesheet>

    我现在使用此XSLT收到的错误输出：

    <?xml version="1.0" encoding="UTF-8"?>
<s:Envelope xmlns:a="http://www.w3.org/2005/08/addressing" xmlns:s="http://www.w3.org/2003/05/soap-envelope">
  <s:Header>
    <a:Action s:mustUnderstand="1">http://www.ortec.com/CAIS/IApplicationIntegrationService/SendMessage</a:Action>
  </s:Header>
  <s:Body>
    <cais:SendMessage xmlns:cais="http://www.ortec.com/CAIS">
      <cais:message>
        <test xmlns:SOAP-ENV="http://schemas.xmlsoap.org/soap/envelope/">
          <element1>123</element1>
          <element2>123</element2>
        </test>
      </cais:message>
      <cais:commandName>Import</cais:commandName>
    </cais:SendMessage>
  </s:Body>
</s:Envelope>

    我希望的输出：

    <?xml version="1.0" encoding="UTF-8"?>
<s:Envelope xmlns:a="http://www.w3.org/2005/08/addressing" xmlns:s="http://www.w3.org/2003/05/soap-envelope">
  <s:Header>
    <a:Action s:mustUnderstand="1">http://www.ortec.com/CAIS/IApplicationIntegrationService/SendMessage</a:Action>
  </s:Header>
  <s:Body>
    <cais:SendMessage xmlns:cais="http://www.ortec.com/CAIS">
      <cais:message>
        <![CDATA[
        <test>
          <element1>123</element1>
          <element2>123</element2>
        </test>
        ]]>
      </cais:message>
      <cais:commandName>Import</cais:commandName>
    </cais:SendMessage>
  </s:Body>
</s:Envelope>

2 个答案:

答案 0 :(得分：8)

可能会做以下工作吗？：

<xsl:template match="SOAP-ENV:Body">
    <xsl:element name="s:{local-name()}" namespace="http://www.w3.org/2003/05/soap-envelope">
        <xsl:element name="cais:SendMessage" namespace="http://www.ortec.com/CAIS">
            <xsl:element name="cais:message" namespace="http://www.ortec.com/CAIS">
                <!-- copy the rest -->
                <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
                <xsl:apply-templates select="child::node()"/>
                <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
            </xsl:element>
            <xsl:element name="cais:commandName" namespace="http://www.ortec.com/CAIS">Import</xsl:element>
        </xsl:element>
    </xsl:element>
</xsl:template>

当我以这种方式修改XSLT并在您的示例输入上运行它时，我得到：

<s:Envelope xmlns:s="http://www.w3.org/2003/05/soap-envelope">
  <s:Header><a:Action s:mustUnderstand="1" xmlns:a="http://www.w3.org/2005/08/addressing">http://www.ortec.com/CAIS/IApplicationIntegrationService/SendMessage</a:Action></s:Header>
  <s:Body><cais:SendMessage xmlns:cais="http://www.ortec.com/CAIS"><cais:message>
  <![CDATA[
    <test xmlns:SOAP-ENV="http://schemas.xmlsoap.org/soap/envelope/">
      <element1>123</element1>
      <element2>123</element2>
    </test>
  ]]>
  </cais:message>
  <cais:commandName>Import</cais:commandName></cais:SendMessage></s:Body>
</s:Envelope>

命名空间声明仍然存在，但这并不重要。

如果你真的想摆脱<test>上的命名空间声明，你可以用这个替换你的身份模板：

  <xsl:template match="@* | node()" priority="-2">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="*">
    <xsl:element name="{name()}">
      <xsl:apply-templates select="@* | node()" />
    </xsl:element>
  </xsl:template>

我已经证实这似乎有效。

另外，如果您提前知道元素的前缀和名称，则无需使用xsl:element或namespace属性。如果在xsl:spreadsheet元素中声明名称空间：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
                   xmlns:xs="http://www.w3.org/2001/XMLSchema" 
                   xmlns:fn="http://www.w3.org/2005/xpath-functions" 
                   xmlns:SOAP-ENV="http://schemas.xmlsoap.org/soap/envelope/" 
                   xmlns:s="http://www.w3.org/2003/05/soap-envelope"
                   xmlns:cais="http://www.ortec.com/CAIS"
                   exclude-result-prefixes="fn xs SOAP-ENV cais">

然后你可以这样做：

<xsl:template match="SOAP-ENV:Body">
    <xsl:element name="s:{local-name()}">
        <cais:SendMessage>
            <cais:message>
                <!-- copy the rest -->
                <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
                <xsl:apply-templates select="child::node()"/>
                <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
            </cais:message>
            <cais:commandName>Import</cais:commandName>
        </cais:SendMessage>
    </xsl:element>
</xsl:template>

答案 1 :(得分：1)

将copy-namespace="no"与xsl:copy-of元素一起使用，以避免在test元素中绑定命名空间：

<xsl:template match="SOAP-ENV:Body">
 <xsl:element name="s:{local-name()}">
   <xsl:element name="cais:SendMessage">
   <xsl:element name="cais:message">
   <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
   <xsl:copy-of select="test" copy-namespaces="no"/>
   <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
  </xsl:element>
  <xsl:element name="cais:commandName"><xsl:text>Import</xsl:text>
</xsl:element>
  </xsl:element>
 </xsl:element>
</xsl:template>
</xsl:stylesheet>
相关问题
最新问题