Question

有没有办法让卸载文件（JPEG，DLL，PNG ...）留在unins000.exe内？如果是，请显示代码。

Answer 1

没有办法做到这一点。 Inno卸载引擎不能包含嵌入文件。

但另一方面也没有特别需要这样做 - 你可以安装它需要的任何文件（如果你想保持整洁，可以安装到app文件夹的子文件夹中）。

将安装文件嵌入到安装程序中的唯一真正原因是它使下载更容易。卸载程序没有这个借口。

Answer 2

Inno Setup对嵌入文件没有本机支持。

但是有了一些创造力，你可以将文件嵌入到代码中（以某种常量的形式）。

不幸的是，在处理二进制数据时，Unicode Inno Setup非常有限，因为它倾向于尝试将所有内容转换为UTF-8。但经过多次尝试后，我最终得到了一些工作代码（使用从Inno Setup preprocessor调用的PowerShell代码）。

将此代码添加到[Code]部分的前面：

function CryptStringToBinary(
  sz: string; cch: LongWord; flags: LongWord; binary: string; var size: LongWord;
  skip: LongWord; flagsused: LongWord): Integer;
  external 'CryptStringToBinaryW@crypt32.dll stdcall';

const
  CRYPT_STRING_HEX = $04;

procedure WriteBinaryStringToStream(S: string; Stream: TStream);
var
  Buffer: string;
  Size: LongWord;
begin
  SetLength(Buffer, (Length(S) div 4) + 1);
  Size := Length(S) div 2;
  if (CryptStringToBinary(S, Length(S), CRYPT_STRING_HEX, Buffer, Size, 0, 0) = 0) or
     (Size <> Length(S) div 2) then
  begin
    RaiseException('Error decoding binary string');
  end;

  Stream.WriteBuffer(Buffer, Size);
end;  

function StreamFromBinaryString(S: string): TStream;
begin
  Result := TStringStream.Create('');
  WriteBinaryStringToStream(S, Result);
  Result.Position := 0;
end;

procedure LoadBitmapFromBinaryString(Bitmap: TBitmap; S: string);
var
  Stream: TStream;
begin
  Stream := StreamFromBinaryString(S);
  try
    Bitmap.LoadFromStream(Stream);
  finally
    Stream.Free;
  end;
end;

procedure SaveBinaryStringToFile(FileName: string; S: string);
var
  Stream: TStream;
begin
  Stream := TFileStream.Create(FileName, fmCreate);
  try
    WriteBinaryStringToStream(S, Stream);
  finally
    Stream.Free;
  end;
end;

#define FileToBinaryString(str FileName) \
  Local[4] = ExtractFileName(FileName), \
  Local[0] = AddBackslash(GetEnv("TEMP")) + Local[4] + ".pas", \
  Local[1] = \
    "-ExecutionPolicy Bypass -Command """ + \
    "Write-Host 'Generating code for " + Local[4] + "'; " + \
    "$bytes = [System.IO.File]::ReadAllBytes('" + FileName + "'); " + \
    "$s = '''' + (($bytes | foreach { $_.ToString('X2') }) -join '') + ''''; " + \
    "Set-Content -Path '" + Local[0] + "' -Value $s;" + \
    """", \
  Exec("powershell.exe", Local[1], SourcePath, , SW_HIDE), \
  Local[2] = FileOpen(Local[0]), \
  Local[3] = FileRead(Local[2]), \
  FileClose(Local[2]), \
  DeleteFileNow(Local[0]), \
  Local[3]

然后你可以使用FileToBinaryString preprocessor macro在编译时（或者更确切地说，在预处理时）将文件转换为十六进制字符串，如：

'4D5A50000200000004000F00FFFF0000B8000....'

在运行时，您将十六进制字符串与一些函数WriteBinaryStringToStream，StreamFromBinaryString，LoadBitmapFromBinaryString或SaveBinaryStringToFile一起使用。

例如，要将位图加载到TBitmapImage，请使用：

LoadBitmapFromBinaryString(
  BitmapImage.Bitmap, {#FileToBinaryString("C:\path\WizModernSmallImage.bmp")});

在编译时，它会转换为如下代码：

LoadBitmapFromBinaryString(
  BitmapImage.Bitmap, '4D5A50000200000004000F00FFFF0000B8000....');

要提取DLL，请使用：

SaveBinaryStringToFile(
  ExpandConstant('{tmp}\InnoCallback.dll'), {#FileToBinaryString("InnoCallback.dll")});

要使用在运行时提取的DLL，您必须使用delayload flag：

function WrapTimerProc(callback:TTimerProc; paramcount:integer):longword;
  external 'wrapcallback@{tmp}\innocallback.dll stdcall delayload';

预处理器/ Pascal编译器对字符串的限制大约为100M字符。虽然对于大于约20-30 MB的文件，您实际上会首先达到PowerShell脚本的[编译时]内存限制。虽然对于较小的大小（大于几MB），但PowerShell脚本的编译时性能很差。尽管如此，该脚本可以进行优化。

由于十六进制编码，安装程序的大小增加了两倍。这可以通过使用一些更有效的编码来改进，例如Base64（CRYPT_STRING_BASE64）。与[Files]部分中包含的文件相比，代码部分甚至没有被压缩（对于图像来说不是问题，因为它们已经被压缩，但是例如对DLL有所不同）。

此解决方案最初是针对问题Inno Setup: Reading a file from installer during uninstallation 开发的。

该代码需要Unicode版本的Inno Setup。在21世纪，你不应该使用Ansi版本。虽然具有讽刺意味的是，在Ansi版本中实现这一点会更容易。有关使用与Anso和Unicode版Inno Setup兼容的CryptStringToBinary，请参阅my answer to Writing binary file in Inno Setup。虽然在Ansi版本中，您实际上可以使用二进制字符串，而不是十六进制字符串。

如何在卸载程序中保留卸载文件？

2 个答案: