Question

我使用 lineto 函数绘制图像画布，然后打印出来。但打印机创建一个空页面.i使用printer.canvas.StretchDraw但如果图像已保存然后加载，图像打印将成功。谁知道原因？

Answer 1

以下是我使用的内容：

function PrintWrapper(ADrawProc : TDrawProc;
                      APreview: Boolean;
                      AWidth, AHeight : longint) : boolean;
var
  bmp : Graphics.TBitmap;
  PixPerInchX, PixPerInchY : longint;
begin
  bmp := Graphics.TBitmap.Create;
  try
    if APreview then begin
      PixPerInchX := GetDeviceCaps(bmp.Canvas.Handle, LOGPIXELSX);
      PixPerInchY := GetDeviceCaps(bmp.Canvas.Handle, LOGPIXELSY);
      bmp.Width := PixPerInchX * AWidth;
      bmp.Height := PixPerInchY * AHeight;
      bmp.Canvas.Brush.Color := clWhite;
      bmp.Canvas.FillRect(Rect(0,0,bmp.Width,bmp.Height));
      ADrawProc(bmp.Canvas,AWidth,AHeight);
      result := (not APreview) or TFormImagePrintPreview.PrintNow(bmp);
      if not result then
        exit;
    end;
    Printer.Orientation := poLandscape;
    Printer.BeginDoc;
    try
      ADrawProc(Printer.Canvas,AValues,AWidth,AHeight);
    finally
      Printer.EndDoc;
    end;
    result := true;
  finally
    FreeAndNil(bmp);
  end;
end;

DrawProc在哪里：

type
  TDrawProc = procedure(ACanvas : TCanvas;
                        Width, Height : longint);

图像预览为：

unit formImagePreviewDef;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls;

type
  TformImagePrintPreview = class(TForm)
    pnBottom: TPanel;
    btPrint: TButton;
    btCancel: TButton;
    imgMain: TImage;
    lbNotes: TLabel;
    procedure btPrintClick(Sender: TObject);
    procedure btCancelClick(Sender: TObject);
  public
    procedure Init(AGraphic : TGraphic; ANotes : string = '');
    class function  PrintNow(AGraphic : TGraphic; ANotes : string = '') : boolean;
  end;

implementation

{$R *.dfm}

{ TformImagePrintPreview }

procedure TformImagePrintPreview.btCancelClick(Sender: TObject);
begin
  Close;
  ModalResult := mrCancel;
end;

procedure TformImagePrintPreview.btPrintClick(Sender: TObject);
begin
  Close;
  ModalResult := mrOk;
end;

procedure TformImagePrintPreview.Init(AGraphic: TGraphic; ANotes : string = '');
const
  MAXSIZE = 600;
begin
  lbNotes.caption := ANotes;
  imgMain.Picture.Assign(AGraphic);
  if AGraphic.Height > AGraphic.Width then begin
    ClientWidth := trunc(MAXSIZE * AGraphic.Width / AGraphic.Height);
    ClientHeight := MAXSIZE + pnBottom.Height;
  end else begin
    Width := MAXSIZE;
    Height := trunc(MAXSIZE * AGraphic.Height/ AGraphic.Width)+pnBottom.Height;
  end;
end;

class function TformImagePrintPreview.PrintNow(AGraphic: TGraphic; ANotes : string = ''): boolean;
var
  form : TformImagePrintPreview;
begin
  form := TformImagePrintPreview.Create(nil);
  try
    form.Init(AGraphic,ANotes);
    result := form.ShowModal = mrOk;
  finally
    FreeAndNil(form);
  end;
end;

end.

Answer 2

也许您忽略了打印页面与屏幕页面的分辨率不同的事实您要在打印画布上绘制的点应乘以一个因子，如Zartog在其示例中使用的那样：

  PixPerInchX := GetDeviceCaps(bmp.Canvas.Handle, LOGPIXELSX);
  PixPerInchY := GetDeviceCaps(bmp.Canvas.Handle, LOGPIXELSY);
  bmp.Width := PixPerInchX * AWidth;
  bmp.Height := PixPerInchY * AHeight;

以下是有关如何打印的简单教程：Printing Directly from Delphi

（delphi）打印图像问题

2 个答案: