Question

Windows资源管理器有一个箭头，指示列表视图（在报表视图样式中）的哪个列按哪个方向排序（ASC与DESC）。

是否可以在Delphi的TListView上显示这样的排序指示箭头？

Answer 1

以下是将标题列标记为升序排序的一些简单代码：

uses
  Winapi.CommCtrl;

var
  Header: HWND;
  Item: THDItem;
begin
  Header := ListView_GetHeader(ListView1.Handle);
  ZeroMemory(@Item, SizeOf(Item));
  Item.Mask := HDI_FORMAT;
  Header_GetItem(Header, 0, Item);
  Item.fmt := Item.fmt and not (HDF_SORTUP or HDF_SORTDOWN);//remove both flags
  Item.fmt := Item.fmt or HDF_SORTUP;//include the sort ascending flag
  Header_SetItem(Header, 0, Item);
end;

为简单起见，我省略了错误检查。如果你想要箭头反方向，我相信你可以找出如何交换逻辑。

密钥MSDN主题是HDITEM结构的主题。

Answer 2

您可以轻松扩展此代码，使其适用于ListView中的所有列;声明两个变量（在Form的私有部分中）：

ColumnToSort：整数; 升序：布尔值;

在FormCreate过程中使用0和True初始化它们。

procedure TForm1.ListView1ColumnClick(Sender: TObject; Column: ListColumn);
var
  Header: HWND;
  Item: THDItem;
begin
  Header := ListView_GetHeader(ListView1.Handle);
  ZeroMemory(@Item, SizeOf(Item));
  Item.Mask := HDI_FORMAT;

  // Clear the previous arrow
  Header_GetItem(Header, ColumnToSort, Item);
  Item.fmt := Item.fmt and not (HDF_SORTUP or HDF_SORTDOWN);//remove both flags
  Header_SetItem(Header, ColumnToSort, Item);

  if Column.Index = ColumnToSort then
    Ascending := not Ascending
  else
    ColumnToSort := Column.Index;

  // Get the new column
  Header_GetItem(Header, ColumnToSort, Item);
  Item.fmt := Item.fmt and not (HDF_SORTUP or HDF_SORTDOWN);//remove both flags

  if Ascending then
    Item.fmt := Item.fmt or HDF_SORTUP//include the sort ascending flag
  else
    Item.fmt := Item.fmt or HDF_SORTDOWN;//include the sort descending flag
  Header_SetItem(Header, ColumnToSort, Item);

  with ListView1 do
    begin
      Items.BeginUpdate;
      AlphaSort;
      Items.EndUpdate;
    end;
end;

当然，您必须提供自己的OnCompare函数来实际排序列。此代码仅显示单击列标题中的排序箭头。

如何在TListView列上显示排序箭头？

2 个答案: