Question

我一直在拼命想要制作一个引导装载程序。在某一点上，我得到它的工作，但现在它不再工作了。当我运行它时，它打印A和B.所以这意味着它确实执行读取，但由于某些原因，当它跳转时它不会执行我放在USB驱动器的第二个扇区的代码。

我想知道我的地址或跳跃是否有问题？

我收录了USB存储器的图像

[bits 16]
[org 0x7C00]

jmp Start

;%include "BIOS_Parameter_Block.inc"
;%include "Extensions.inc"
;%include "Print.inc"

; Prepare Stack Segment
;-----------------------------------------------------------------
Start:
xor ax, ax
mov ds, ax
mov es, ax
mov fs, ax
mov gs, ax
mov ss, ax

mov sp, 0x7C00              ; Move Stack into SP
mov bp, sp                  ; Store current Stack Base

; Print Character to Make Sure Bootloader Has Reached this Point
;-----------------------------------------------------------------
mov ah, 0x0E                ; Print Character to Screen
mov bh, 0x00                ; No Page Numbering
mov bl, 0x07                ; White Text, Black Background
mov al, 65                  ; Print Letter A
int 0x10

; Check if INT0x13 Extentions are Supported
;-----------------------------------------------------------------
mov ah, 0x41                ; Set Function 0x41
mov word bx, 0x55AA          
push dx                     ; Save old Drive Identifier
mov dl, 0x80                ; Load 'Active' ID Into dl
int 0x13                    ; Call Interupt
jc short unsupported        ; If Extentions aren't Supported, Jump
clc                         ; Clear Carry Bit

; Read from the device.
;-----------------------------------------------------------------
mov si, DAPS                ; Load DAPS Struct to DS:SI
mov ah, 0x42                ; Read Functions (AL Ignored)
mov dl, 0x80                ; Load 'Active' ID Into dl
int 0x13
jc short unsupported        ; If something goes wrong...

mov ah, 0x0E                ; Print Character to Screen
mov bh, 0x00                ; No Page Numbering
mov bl, 0x07                ; White Text, Black Background
mov al, 66                  ; Print Letter B
int 0x10

; IT DOES PRINT THIS ABOVE

jmp 0x0:0x7E00                  ; Jump to main

; Errors 
;-----------------------------------------------------------------
unsupported:
mov ah, 0x0E                ; Print Letter F, Gives Indication of Failure
mov bh, 0x00
mov bl, 0x07
mov al, 70
int 0x10

clc
hlt
; Memory Data Structures and Other Variables
;-----------------------------------------------------------------
; Disk Address Packet Structure (Used For Loading Rest of OS)
DAPS: db 0x10               ; Size of Structure (16 bytes)
      db 0                  ; Always 0
      dw 1                  ; Number of Sectors to Read (1x512)
      dw 0x7E00             ; Offset to load to.
      dw 0x0000             ; Segment to load to.
      dq 1                  ; Read from Second Block

; Fill Out Rest of Bootloader
;-----------------------------------------------------------------
times 510-($-$$) db 0

db 0x55, 0xAA               ; Add Boot Record Signature

Stage2位于第二个扇区

 [ORG 0x7E00]
 [bits 16]

 mov ah, 0x0E                ; Print Character to Screen
 mov bh, 0x00                ; No Page Numbering
 mov bl, 0x07                ; White Text, Black Background
 mov al, 67                  ; Print Letter C
 int 0x10
 cli
 hlt

希望你们能帮助我！

Memory of Bootloader

Answer 1

int 0x13 bios调用通常使用DL寄存器中的驱动器ID - 0x80通常是第一个HDD的ID。您可能需要更改此设置才能从USB驱动器（可能不是第一个HDD）加载其他扇区。

Bootloader - 不正确jmp或加载第二个扇区

1 个答案: