Question

好的，我是一个ActionScript noob。我可以“点击这里去那里”那种东西，所有的时间线编写。

然后我将这个项目倾倒在我的腿上（因为我是“Flash Guy”）虽然我已经阅读了一些有意义的东西，但我需要有人告诉我究竟在哪里编码。我保证一旦结束就回去学习真正的AS3，我有书和一本好的教程。

这是任务。我有一个SWF文件（我们称之为parent.swf），要求用户在文本字段（hospNameInput）中输入名称，并将其保存到变量（hName）。

var hName:String;

hospNameInput.addEventListener(Event.CHANGE, inputCapture1);
function inputCapture1(evt:Event):void
{
hName = hospNameInput.text;
}

我需要在另一个SWF（child.swf，由parent.swf加载）中使用字符串变量“hName”，以便将名称文本添加到我文件的许多帧上的文本框中。它本质上是一个美化的幻灯片，在框架上有一些互动性，他们希望能够为他们呈现的人个性化它。

我在child.swf中有文本框，我想在parent.swf中填充变量“hName”中的文本，如：

var frameHeader:String = "01 " + hName + " Today";
frameHeader1.text = frameHeader;
chartLabel.text = hName + " Analysis";

像我说的那样，我只是一个懦弱的时间线编码器。有人可以给我相当明确的指示，说明每个SWF中的内容可以让它工作吗？

我保证会阅读这些书并学习如何正确地执行此操作，外部.as文件以及所有!!

Answer 1

尝试通过Loader对象的content属性访问变量。 content属性应该直接引用加载的swf的时间轴。

http://help.adobe.com/en_US/FlashPlatform/reference/actionscript/3/flash/display/Loader.html?filter_flash=cs5&filter_flashplayer=10.2&filter_air=2.6#content

Answer 2

对于仍然遇到此问题的人，您可以尝试以下步骤......

您必须使用代码创建文本框。首先将输入框添加到舞台
加载外部SWF并将其视为MovieClip对象。
将文本框（带有已保存的输入）添加到MovieClip（已加载的SWF）。

下面有一些示例代码可供尝试。它添加了一个输入框，当用户单击“加载SWF”按钮时，它会加载外部SWF，然后添加带有输入文本副本的文本框。要制作一个“加载SWF”按钮，只需创建一个简单的图形，如红色方块，转换为movieClip并为其指定引用名称“btn_load_SWF”。（代码仍然会像按钮一样工作）。此外，当您按代码创建文本框时，您可能需要在X＆amp;您希望它们出现的Y位置。使用信息工具（CTRL + I）获取舞台上鼠标/对象位置的提示。无论如何，所有代码都在一帧中。

//-- For later referencing of Child.swf as though it's MovieClip on stage named   "my_Child_Swf"
var my_Child_Swf:MovieClip;

//-- create User Input textbox
var input_txt:TextField = new TextField();
input_txt.type = "input";
input_txt.border = true;
input_txt.x = 50;
input_txt.y = 100;

//-- create string to hold User Input for passing onto a Child.swf textbox
var saved_text:String;

//-- create Name textbox for Child.swf (later will contain text of "saved_text") 
var name_txt:TextField = new TextField();
name_txt.type = "dynamic";
//name_txt.border = true;
name_txt.x = 10;
name_txt.y = 10;
name_txt.width = 50;

//-- Now add User Input box to screen 
stage.addChild(input_txt);

//-- load SWF
var swf_loader:Loader = new Loader(); 

//add loader object to stage BEFORE you do anything with external SWF..
stage.addChild(swf_loader);
btn_load_SWF.buttonMode = true;
btn_load_SWF.addEventListener(MouseEvent.CLICK, load_Child_SWF); 

//Button control function
function load_Child_SWF (event:MouseEvent) : void 
{ 
  saved_text = input_txt.text; //capture text as we begin load of Child SWF
  trace("input_txt is..." + saved_text); //trace is for testing/confirmation

  swf_loader.load ( new URLRequest ("Child.swf") );
  swf_loader.contentLoaderInfo.addEventListener(Event.COMPLETE, Child_SWF_ready);
}  

function Child_SWF_ready (evt:Event) : void
{
  swf_loader.contentLoaderInfo.removeEventListener(Event.COMPLETE, Child_SWF_ready); 
  swf_loader.x = stage.stageWidth / 2; 
  swf_loader.y = 200;

  //Treat the Loader contents (Child.swf) as a MovieClip named "my_Child_Swf"
  my_Child_Swf = swf_loader.content as MovieClip; 

  //Position of text when adding to Child SWF 
  //note: Its top-left corner is new X & Y point set to 0   
  name_txt.x = 10; //10 pixels from 0 point of Child SWF
  name_txt.y = 10;

  updateText(); //do instructions inside function "updateText"
  my_Child_Swf.addChild(name_txt); //add (updated) name text to Child SWF 

}

function updateText() : void
{
  name_txt.text = saved_text; //apply the saved_input String here
}

这应该足以让你入门。其他需要注意的是如何设置和嵌入字体，设置文字大小和颜色等等通过代码。对于记录，在时间轴中进行任何编码并不是最好的工作方式。我将所有代码放在一个地方，即.as文件中。我无法预测当你转移到另一个框架时会发生什么？代码集。话虽这么说，这是从时间表和工作测试。谢谢，VC：一个

从另一个SWF文件访问SWF文件中的变量

2 个答案: